지돌스타 - 쿠키랩 블로그

• Squiggly 다운로드 : http://labs.adobe.com/downloads/squiggly.html
• Squiggly ASDoc : http://download.macromedia.com/pub/labs/squiggly/squiggly_p2_asdoc_122109.zip
  

이것을 쓸지 모르겠지만 아무튼 알아두고 있어 나쁠 것도 없으니....

참고
http://adnaru.com/242

글쓴이 : 지돌스타(http://blog.jidolstar.com/640)

• AS3 Code Libraries 
• 유용한 ActionScript 3.0 라이브러리 #1 
• 유용한 ActionScript 3.0 라이브러리 #2

• Away3D 라이브러리 : http://away3d.googlecode.com/svn/trunk/fp10/Away3D 
• Away3DLite 라이브러리 : http://away3d.googlecode.com/svn/trunk/fp10/Away3DLite
• Away3D 라이브러리 예제 : http://away3d.googlecode.com/svn/trunk/fp10/Examples/Away3D/as/ 
• Away3DLite 라이브러리 예제 : http://away3d.googlecode.com/svn/trunk/fp10/Examples/Away3DLite/as/

여러분은 Papervision3D를 SVN으로 프로젝트를 만든 것처럼 Away3D에서도 그래도 하면 된다. 단. Examples의 경우 중간에 프로젝트 생성시 ActionScript 프로젝트를 선택하기 바란다. 물론 Flash Player 10 기준이라는 점도 명심하자.

예제 프로젝트에서는 해당 라이브러리 프로젝트의 경로를 포함시켜줘야한다. Away3D_Example은 Away3D 라이브러리를 Away3DLite_Examples는 Away3dLite 라이브러리를 포함해야한다. 방법은 간단하다. Away3D_Example와 Away3DLite_Examples내에 libs 폴더안에 각각의 라이브러리 프로젝트에서 만들어진 bin디렉토리에 있는 
swc를 복사하면 된다. 하지만 이는 애플리케이션을 전부 만들고 배포하고 난 다음에 백업을 위해 선택할 방법이고 실제로 개발할때는 다음과 같이 한다.

1. Away3D_Example 프로젝트를 선택한다.
2. 메뉴에서 Project > Properties를 선택한다.
3. 창이 뜨면 좌측 ActionScript Build Path(Flex의 경우 Flex Build Path)를 선택한다.
4. 상단 Library path 탭을 선택한다.
5. Add Project를 선택한 다음 Away3D 라이브러리를 선택한다.
6. OK 버튼을 누른다.
7. Away3D_Example의 .actionScriptProperties를 연다.
아래 그림처럼  default package에 있는 소스 들은 전부 애플리케이션들이다. 이 코드들이 진정한 애플리케이션으로서 동작하려면 .actionScriptProperties내에 application으로 등록해야한다. 수작업이긴 해도 전부 등록하자. 또는 해당 as 파일을 선택후 마우스 오른쪽 버튼을 눌러 Set as Default Application 항목을 선택해도 된다. 이는 애플리케이션으로 등록하는 동시에 Default 애플리케이션으로 잡아준다. Default 애플리케이션을 지칭하는 것은 .actionScriptProperties 파일 내에 actionScriptProperties 태그의 mainApplicationPath 속성이 그 역할을 한다.

이 캐스트는 베스트 No.로 12월 10일에 추천되었습니다. ^^
http://opencast.naver.com/home/bestNo.nhn?exposureDate=20091210 

글쓴이 : 지돌스타(http://blog.jidolstar.com/633)

1. 새로운 기능 (이번 페이지에서 다룸)
   - File Promises
   - Screen reader
   - Native Processes
   - New networking support
   - Global Error Handling
   - Packaging an AIR application in a native installer
   
2. 기존 API에 대한 추가된 기능 (다음 편에 다룸)
   - Max Size of NativeWindow
   - Idle time-out
   - Mac Vector Printing
   - Database Transaction Savepoints
   - Microphone Access API
   - Open file with Default Application
   
3. 플랫폼 인식 관련 API (다음 편에 다룸)
   - Multi-touch functionality
   - Mass Storage Device Detection
   
4. 퍼포먼스 향상 (다음 편에 다룸)

출처 : http://tinyurl.com/ydxevnu

• (Adobe 문서)IPv6 addresses
• http://ko.wikipedia.org/wiki/IPv6

• Networking
  

• TCP에 대해
  

• (Adobe 문서)Server sockets
• ServerSocket 클래스 
• 머드초보님의 ServerSocket을 이용한 간단한 채팅서버 만들기
• Creating a socket server in Adobe AIR 2 
• A Demonstration of the ServerSocket API in AIR 2

• UDP 소켓 프로그래밍 

• (Adobe 문서)UDP sockets (AIR)  
• DatagramSocket 클래스

• (Adobe 문서) Secure client sockets(AIR)
• SecureSocket 클래스
• A Demonstration of Encrypted Socket Support in AIR 2

• (Adobe 문서)Network Interfaces
• NetworkInfo 클래스 
• NetworkInterface 클래스
• InterfaceAddress 클래스

package { 
	import flash.display.Sprite; 
	import flash.net.InterfaceAddress; 
	import flash.net.NetworkInfo; 
	import flash.net.NetworkInterface; 
	
	public class NetworkInformationExample extends Sprite 
	{ 
		public function NetworkInformationExample() 
		{ 
			var networkInfo:NetworkInfo.<NetworkInterface> = NetworkInfo.networkInfo;
			var interfaces:Vector.<NetworkInterface> = networkInfo.findInterfaces(); 
			
			if( interfaces != null ) 
			{ 
				trace( "Interface count: " + interfaces.length ); 
				for each ( var interfaceObj:NetworkInterface in interfaces ) 
				{ 
					trace( "\nname: "             + interfaceObj.name ); 
					trace( "display name: "     + interfaceObj.displayName ); 
					trace( "mtu: "                 + interfaceObj.mtu ); 
					trace( "active?: "             + interfaceObj.active ); 
					//trace( "default?: "         + interfaceObj.networkInterfaceDefault ); 
					trace( "parent interface: " + interfaceObj.parent ); 
					trace( "hardware address: " + interfaceObj.hardwareAddress ); 
					if( interfaceObj.subInterfaces != null ) 
					{ 
						trace( "# subinterfaces: " + interfaceObj.subInterfaces.length ); 
					} 
					trace("# addresses: "     + interfaceObj.addresses.length ); 
					for each ( var address:InterfaceAddress in interfaceObj.addresses ) 
					{ 
						trace( "  type: "           + address.ipVersion ); 
						trace( "  address: "         + address.address ); 
						trace( "  broadcast: "         + address.broadcast ); 
						trace( "  prefix length: "     + address.prefixLength ); 
					} 
				}             
			} 
		}     
	} 
}

• DNSResolver 클래스
• (레코드 타입)ARecord
• (레코드 타입)AAARecord
• (레코드 타입)SRVRecord
• (레코드 타입)MXRecord
• (레코드 타입)PTRRecod
• (Adobe 문서)DNS 레코드

package
{
	import flash.desktop.NativeApplication;
	import flash.display.Sprite;
	import flash.events.DNSResolverEvent;
	import flash.events.ErrorEvent;
	import flash.net.dns.AAAARecord;
	import flash.net.dns.ARecord;
	import flash.net.dns.DNSResolver;
	import flash.net.dns.MXRecord;
	import flash.net.dns.PTRRecord;
	import flash.net.dns.SRVRecord;
	import flash.utils.getQualifiedClassName;
	
	public class DNSResolverExample extends Sprite
	{
		private var lookupCount:int = 0;
		public function DNSResolverExample()
		{
			//Create the resolver object
			var resolver:DNSResolver = new DNSResolver();
			resolver.addEventListener( DNSResolverEvent.LOOKUP, lookupComplete );
			resolver.addEventListener( ErrorEvent.ERROR, lookupError );
			
			//Look up records
			resolver.lookup( "yahoo.com", ARecord );
			resolver.lookup( "yahoo.com", AAAARecord );
			resolver.lookup( "yahoo.com", MXRecord );
			resolver.lookup( "209.191.93.53", PTRRecord );
			resolver.lookup( "_sip._tcp.yahoo.com.", SRVRecord );
		}
		
		private function lookupComplete( event:DNSResolverEvent ):void
		{
			trace("-------------------------------------");
			trace( "Query string: " + event.host );
			trace( "Record type: " +  flash.utils.getQualifiedClassName( event.resourceRecords[0] ) + 
				", count: " + event.resourceRecords.length );
			for each( var record:* in event.resourceRecords )
			{
				if( record is ARecord ) trace( record.name + " : " + record.address );
				if( record is AAAARecord ) trace( record.name + " : " + record.address );
				if( record is MXRecord ) trace( record.name + " : " + record.exchange + ", " + record.preference );
				if( record is PTRRecord ) trace( record.name + " : " + record.ptrdName );
				if( record is SRVRecord ) trace( record.name + " : " + record.target + ", " + record.port +
					", " + record.priority + ", " + record.weight );
			}    
			if( ++lookupCount == 5 )
			{
				NativeApplication.nativeApplication.exit();
			}
		}
		
		private function lookupError( error:ErrorEvent ):void
		{
			trace("-------------------------------------");
			trace("Error: " + error.text );
			if( ++lookupCount == 5 )
			{
				NativeApplication.nativeApplication.exit();
			}
		}
	}
}

1.5 스크린 리더 지원(Screen Reader Support)

AIR 2.0은 스크린 리더를 지원하기 위한 Accessibility 클래스가 추가되었다. 스크린 리더는 시각 장애 사용자들을 위한 보조 기술로서 화면 내용을 오디오 버전으로 제공하는 것이다. 이 클래스는 현재 Windows 환경에서만 제공된다. 이것이 지원되는지 확인하려면 Capabilities.hasAccessibility 정적속성이 true이어야 한다. 버튼, 무비클립, 텍스트필드와 같은 객체에 액세스 가능한 속성을 얻고 설정하기 위해 DisplayObject.accessibilityProperties 속성을 사용하며 이 값이 바뀌었다는 것을 알려주기 위해 Accessibility.updateProperties() 정적메소드를 이용한다.

• [IT용어 아하!] 스크린 리더 
• Accessibility 클래스
• [열이아빠] RIA가 웹을 불필요한 제약으로 만들고 있나요 - 플렉스에도 접근성을 적용할 수 있나요. 참고

package {
	import flash.accessibility.Accessibility;
	import flash.desktop.NativeApplication;
	import flash.display.Sprite;
	import flash.display.StageAlign;
	import flash.display.StageScaleMode;
	import flash.utils.setTimeout;
	
	public class AccessibilityExample extends Sprite {
		public static const BUTTON_WIDTH:uint = 90;
		public static const BUTTON_HEIGHT:uint = 20;
		
		private var gutter:uint = 5;
		private var menuLabels:Array = new Array("PROJECTS", "PORTFOLIO", "CONTACT");
		private var menuDescriptions:Array = new Array("Learn more about our projects"
			, "See our portfolio"
			, "Get in touch with our team");
		
		public function AccessibilityExample() {
			configureAssets();
			NativeApplication.nativeApplication.autoExit = true;
			stage.align = StageAlign.TOP_LEFT;
			stage.scaleMode = StageScaleMode.NO_SCALE;
			stage.nativeWindow.activate();
			setTimeout(updateAccessibility, 2000); 
		}
		
		private function updateAccessibility():void {
			trace("Accessibility.active: " + Accessibility.active);
			if(Accessibility.active) {
				Accessibility.updateProperties();
			}
		}
		
		private function configureAssets():void {
			var child:CustomAccessibleButton;
			for(var i:uint; i < menuLabels.length; i++) {
				child = new CustomAccessibleButton();
				child.y = (numChildren * (BUTTON_HEIGHT + gutter));
				child.setLabel(menuLabels[i]);
				child.setDescription(menuDescriptions[i]);
				addChild(child);
			}
		}
	}
}

import flash.accessibility.AccessibilityProperties;
import flash.display.Shape;
import flash.display.SimpleButton;
import flash.display.Sprite;
import flash.events.Event;
import flash.text.TextFormat;
import flash.text.TextFormatAlign;
import flash.text.TextField;

class CustomAccessibleButton extends Sprite {
	private var button:SimpleButton;
	private var label:TextField;
	private var description:String;
	private var _name:String;
	
	public function CustomAccessibleButton(_width:uint = 0, _height:uint = 0) {
		_width = (_width == 0) ? AccessibilityExample.BUTTON_WIDTH : _width;
		_height = (_height == 0) ? AccessibilityExample.BUTTON_HEIGHT : _height;
		
		button = buildButton(_width, _height);
		label = buildLabel(_width, _height);
		
		addEventListener(Event.ADDED, addedHandler);
	}
	
	private function addedHandler(event:Event):void {
		trace("addedHandler: " + this._name);
		var accessProps:AccessibilityProperties = new AccessibilityProperties();
		accessProps.name = this._name;
		accessProps.description = description;
		accessibilityProperties = accessProps;
		removeEventListener(Event.ADDED, addedHandler);
	}
	
	private function buildButton(_width:uint, _height:uint):SimpleButton {
		var child:SimpleButton = new CustomSimpleButton(_width, _height);
		addChild(child);
		return child;
	}
	
	private function buildLabel(_width:uint, _height:uint):TextField {
		var format:TextFormat = new TextFormat();
		format.font = "Verdana";
		format.size = 11;
		format.color = 0xFFFFFF;
		format.align = TextFormatAlign.CENTER;
		format.bold = true;
		
		var child:TextField = new TextField();
		child.y = 1;
		child.width = _width;
		child.height = _height;
		child.selectable = false;
		child.defaultTextFormat = format;
		child.mouseEnabled = false;
		
		addChild(child);
		return child;
	}
	
	public function setLabel(text:String):void {
		label.text = text;
		this._name = text;
	}
	
	public function setDescription(text:String):void {
		description = text;
	}
}

class CustomSimpleButton extends SimpleButton {
	private var upColor:uint = 0xFFCC00;
	private var overColor:uint = 0xCCFF00;
	private var downColor:uint = 0x00CCFF;
	
	public function CustomSimpleButton(_width:uint, _height:uint) {
		downState = new ButtonDisplayState(downColor, _width, _height);
		overState = new ButtonDisplayState(overColor, _width, _height);
		upState = new ButtonDisplayState(upColor, _width, _height);
		hitTestState = new ButtonDisplayState(upColor, _width, _height);
		useHandCursor = true;
	}        
}

class ButtonDisplayState extends Shape {
	private var bgColor:uint;
	private var _width:uint;
	private var _height:uint;
	
	public function ButtonDisplayState(bgColor:uint, _width:uint, _height:uint) {
		this.bgColor = bgColor;
		this._width = _width;
		this._height = _height;
		draw();
	}
	
	private function draw():void {
		graphics.beginFill(bgColor);
		graphics.drawRect(0, 0, _width, _height);
		graphics.endFill();
	}
}

• (Adobe 문서) Communicating with native processes in AIR 
• NativeProcess 클래스 
• NativeProcessStartupInfo 클래스
• A Demonstration of the NativeProcess APIs in AIR 2
• (찬익)Adobe AIR 2.0의 NativeProcess와 Native Installer
  

<supportedProfiles>extendedDesktop</supportedProfiles>

<?xml version="1.0" encoding="utf-8"?>
<s:WindowedApplication xmlns:fx="http://ns.adobe.com/mxml/2009" 
					   xmlns:s="library://ns.adobe.com/flex/spark" 
					   xmlns:mx="library://ns.adobe.com/flex/halo">
	<fx:Script>
		<![CDATA[
			import flash.events.NativeProcessExitEvent;
			
			public function executeNativeProcess():void 
			{
				var executable:File = new File("C:/Program Files/EditPlus 3/editplus.exe"); //c:/Windows/System32/notepad.exe
				var workingDirectory:File = new File("c:/");
				
				var nativeProcess:NativeProcess = new NativeProcess();
				
				if (NativeProcess.isSupported) 
				{
					trace("Native Process Supported");
				}
				
				var nativeProcessStartupInfo:NativeProcessStartupInfo = new NativeProcessStartupInfo();
				nativeProcessStartupInfo.executable = executable;
				nativeProcessStartupInfo.workingDirectory = workingDirectory;
				
				var args:Vector.<String> = new Vector.<String>();   
				args.push("c:/LAN.log"); // open file that was given with the executable application 
				nativeProcessStartupInfo.arguments = args;
				
				nativeProcess.addEventListener( NativeProcessExitEvent.EXIT, onExitError );
				
				try {
					nativeProcess.start(nativeProcessStartupInfo);
				} catch (error:IllegalOperationError) {
					trace("Illegal Operation: "+error.toString());
				} catch (error:ArgumentError) {
					trace("Argument Error: "+error.toString());
				} catch (error:Error) {
					trace ("Error: "+error.toString());
				}
				
				if (nativeProcess.running) 
				{
					trace ("Native Process Support");
				}       
			}
			
			public function onExitError(event:NativeProcessExitEvent):void 
			{
				trace( "Native Process Exit code: "+event.exitCode );
			}            
			
		]]>
	</fx:Script>
	
	<s:Button id="button"
			  label="Open File foobar.txt with text editor"
			  click="executeNativeProcess();"
			  width="250" />
	
</s:WindowedApplication>

• Interacting with a native process(HTML/Javascript)
• Interacting with a native process(Flex 3)
• Interacting with a native process(Flash CS5)
  

<?xml version="1.0" encoding="utf-8"?>
<s:WindowedApplication xmlns:fx="http://ns.adobe.com/mxml/2009" 
					   xmlns:s="library://ns.adobe.com/flex/spark" 
					   xmlns:mx="library://ns.adobe.com/flex/halo" 
					   width="350" height="150"
					   applicationComplete="windowedapplication1_applicationCompleteHandler(event)">
	<fx:Script>
		<![CDATA[
			import flash.events.ProgressEvent;
			import flash.system.Capabilities;
			import flash.utils.IDataInput;
			
			import mx.controls.Alert;
			import mx.events.FlexEvent;
			
			private var process:NativeProcess;
			
			private function windowedapplication1_applicationCompleteHandler(event:FlexEvent):void {
				//Native Process가 지원되는지 확인. 
				//지원되려면 반드시 디스크립터에  <supportedProfiles>extendedDesktop</supportedProfiles>을 추가해야한다.
				if( NativeProcess.isSupported ) {
					launchEchoTest();
				} else {
					Alert.show("NativeProcess not supported.","Error");
				}
			}			
			private function launchEchoTest():void {
				//실행할 Native 애플리케이션 선택
				var file:File = File.applicationDirectory;
				file = file.resolvePath("NativeApps");
				if( Capabilities.os.toLocaleLowerCase().indexOf("win") > -1 ) {
					file = file.resolvePath("Windows/bin/echoTestWin.exe");
				} else {
					file = file.resolvePath("Mac/bin/echoTestMac");
				}
				
				//Native Process를 진행하기 위한 정보 설정 
				var info:NativeProcessStartupInfo = new NativeProcessStartupInfo();
				info.executable = file;
				
				//Native Process생성
				process = new NativeProcess();
				
				//보내고 받을때 발생하는 이벤트에 대한 처리 
				process.addEventListener(ProgressEvent.STANDARD_OUTPUT_DATA, function(event:ProgressEvent):void {
					var date:Date = new Date();
					var bytes:IDataInput = process.standardOutput;
					textReceived.text = bytes.readUTFBytes( bytes.bytesAvailable );
					launchEchoTest();
					lbDateStamp.text = date.toString();
				} );
				process.addEventListener(ProgressEvent.STANDARD_INPUT_PROGRESS, function(event:ProgressEvent):void {
					process.closeInput();
				} );
				//Native Process 시작 
				process.start( info );
			}
			private function writeData():void {
				process.standardInput.writeUTFBytes( textToSend.text + "\n" );
			}
		]]>
	</fx:Script>
	<fx:Declarations>
		<!-- Place non-visual elements (e.g., services, value objects) here -->
	</fx:Declarations>
	<s:VGroup paddingLeft="10" paddingRight="10" paddingTop="10" paddingBottom="10">
		<mx:Form>
			<mx:FormItem label="Text to send" direction="horizontal">
				<s:TextInput id="textToSend"/>	
				<s:Button label="writeData()" click="writeData()"/>
			</mx:FormItem>
			<mx:FormItem label="Text received">
				<s:TextInput id="textReceived" editable="false"/>
			</mx:FormItem>
		</mx:Form>
		<s:Label id="lbDateStamp"/>
	</s:VGroup>
</s:WindowedApplication>

#include <stdio.h>
#include <stdlib.h>
#include <sys/time.h>
#include <sys/types.h>
#include <fcntl.h>
#include <unistd.h>

#define BUFFER_SIZE 8192

int main(int argc, char** argv)
{
	char buf[BUFFER_SIZE];
	int  cnt;
	
	while ( !feof(stdin) )
	{
		cnt = read(STDIN_FILENO, buf, sizeof buf); 
		if (-1 == cnt) 
		{
			perror("read");
			exit(1);
		}
		if (0 == cnt)
		{
			// eof reached...
			exit(0);
		}

		write(STDOUT_FILENO, buf, cnt ); 
	}
	
	return 0;
}

• URLFilePromise 클래스 : http://tinyurl.com/yg5pe32 
• Dropping file promises : http://tinyurl.com/yj8psb6
• A Screencast Explaining and Demoing File Promises
  

다음 코드는 예시이다.

 

<?xml version="1.0" encoding="utf-8"?>
<s:WindowedApplication xmlns:fx="http://ns.adobe.com/mxml/2009" 
					   xmlns:s="library://ns.adobe.com/flex/spark" 
					   xmlns:mx="library://ns.adobe.com/flex/halo"
					   applicationComplete="windowedapplication1_applicationCompleteHandler(event)">
	<fx:Script>
		<![CDATA[
			import mx.controls.Alert;
			import mx.events.DragEvent;
			import mx.events.FlexEvent;
			
			private var clipboard:Clipboard;
			private function windowedapplication1_applicationCompleteHandler(event:FlexEvent):void {
				clipboard = new Clipboard();
				if( !clipboard.supportsFilePromise ) {
					Alert.show( "File Promise를 지원하지 않습니다." );
				}
			}
			private function onDragOut(event:DragEvent):void {
				trace( event.target, event.type );
				var items:Array = fileData.selectedItems;
				var promises:Array = new Array();
				for each (var item:Object in items) {
					var filePromise:URLFilePromise = new URLFilePromise();
					var request:URLRequest = new URLRequest(item.url);
					filePromise.request = request;
					filePromise.relativePath = item.name;
					promises.push(filePromise);
				}
				clipboard.setData(ClipboardFormats.FILE_PROMISE_LIST_FORMAT, promises);
				NativeDragManager.doDrag(fileData, clipboard);     
			}
			private function onDragOutComplete(event:NativeDragEvent):void {
				trace( "Drag out complete");
				clipboard = new Clipboard();
			}            
		]]>
	</fx:Script>
	
	<fx:Declarations>
		<mx:ArrayCollection id="arrColl">
			<mx:source>
				<fx:Array>
					<fx:Object name="rhall.jpg" url="http://a1.twimg.com/profile_images/57117466/robert_m_hall_bio_photo_big_normal.jpg" />
					<fx:Object name="bobjim.jpg" url="http://a1.twimg.com/profile_images/51723308/ryancampbell3_normal.jpg"/>
					<fx:Object name="jenschr.jpg" url="http://a1.twimg.com/profile_images/43222252/jenschr_mugshot3_normal.jpg"/>
					<fx:Object name="adamflater.jpg" url="http://a1.twimg.com/profile_images/21503622/Photo_8_normal.jpg"/>
					<fx:Object name="reboog711.jpg" url="http://a1.twimg.com/profile_images/16984682/DSCF0044_normal.jpg"/>
				</fx:Array>
			</mx:source>
		</mx:ArrayCollection>
	</fx:Declarations>
	
	<mx:DataGrid id="fileData" dragEnabled="true"
				 dataProvider="{arrColl}" 
				 dragStart="onDragOut(event)"
				 nativeDragComplete="onDragOutComplete(event)" width="100%">
		<mx:columns>
			<mx:DataGridColumn dataField="name" width="100"/>
			<mx:DataGridColumn dataField="url"/>
		</mx:columns>
	</mx:DataGrid>
	
</s:WindowedApplication>

• Global Error Handling in AIR 2.0 and Flash 10.1
• UncaughtErrorEvent 클래스
• Loader.uncaughtErrorEvent
• LoaderInfo.uncaughtErrorEvent

package {
	import flash.desktop.*;
	import flash.display.*;
	import flash.events.*;
	public class UncaughtErrorEventExample extends Sprite {
		public function UncaughtErrorEventExample()
		{
			var options:NativeWindowInitOptions = new NativeWindowInitOptions();
			options.type = NativeWindowType.UTILITY;
			
			var window:NativeWindow = new NativeWindow(options);
			window.width = 200;
			window.height = 200;
			window.title = "UncaughtErrorEventExample";
			
			window.stage.scaleMode = StageScaleMode.NO_SCALE;
			window.stage.align = StageAlign.TOP_LEFT;
			
			window.activate();
			window.addEventListener(Event.CLOSING, function($event:Event):void {
				NativeApplication.nativeApplication.exit();
			});			

			var btn:Sprite = new Sprite();
			btn.useHandCursor = true;
			btn.buttonMode = true;
			btn.graphics.clear();
			btn.graphics.beginFill(0xFFCC00);
			btn.graphics.drawRect(0, 0, 100, 50);
			btn.graphics.endFill();
			btn.addEventListener(MouseEvent.CLICK, clickHandler);			
			window.stage.addChild(btn);
			
			loaderInfo.uncaughtErrorEvents.addEventListener(UncaughtErrorEvent.UNCAUGHT_ERROR, uncaughtErrorHandler);
		}
		private function uncaughtErrorHandler(e:UncaughtErrorEvent):void {
			if (e.error is Error) {
				var error:Error = e.error as Error;
				// do something with the error
				trace(error.errorID, error.name, error.message);
			} else if (e.error is ErrorEvent) {
					var errorEvent:ErrorEvent = e.error as ErrorEvent;
					// do something with the error
					trace(errorEvent.errorID);
			} else {
				// a non-Error, non-ErrorEvent type was thrown and uncaught
				trace( " a non-Error, non-ErrorEvent type was thrown and uncaught " );
			}
			e.preventDefault();
		}
		private function clickHandler(event:MouseEvent):void
		{
			throw new Error("Gak!");
		}
	}
}

• Packaging an AIR application in a native installer
  

연관글

• Exhaustive List of Everything That's New in AIR 2.0
• AIR 2 Enhancements Complete Overview
• AIR 2 Rerelease Note
• AIR 2 Public Beta Resources
• Adobe AIR 2.0 Sample 소스 받아가세요.

 <mx:Application xmlns:mx="http://www.adobe.com/2006/mxml">
	<mx:Style>
		MenuBar { 
			font-weight:bold; 
			color:#FFFFFF;
			fill-colors:#0D0A92, #1B16F4, #37920A, #59EB12;
			fill-alphas:1.0,1.0;
		}
		MenuBarItem {
			theme-color:#0000FF;
		}
		Menu { 
			alternatingItemColors:#ffffff,#eff4fa;
			color:#000000;
			top:4px;
			bottom:2px;
			horizontalGap:2px;	
			roll-over-color:#00ff00;
		}
	</mx:Style>
	<mx:MenuBar id="myMenuBar" labelField="@label" >
		<mx:XMLList>
			<menuitem label="MenuItem A">
				<menuitem label="SubMenuItem A-1" enabled="false"/>
				<menuitem label="SubMenuItem A-2"/>
			</menuitem>
			<menuitem label="MenuItem B"/>
			<menuitem label="MenuItem C"/>
			<menuitem label="MenuItem D">
				<menuitem label="SubMenuItem D-1" 
						  type="radio" groupName="one"/>
				<menuitem label="SubMenuItem D-2" 
						  type="radio" groupName="one"
						  selected="true"/>
				<menuitem label="SubMenuItem D-3" 
						  type="radio" groupName="one"/>
			</menuitem>
		</mx:XMLList>
	</mx:MenuBar>
</mx:Application>

Flex SDK 클래스를 보려면 framework.swc를 펼쳐보면 된다.

item.menuBarItemState = "itemDownSkin";

    public function set menuBarItemState(value:String):void
    {
        _menuBarItemState = value;
        viewSkin(_menuBarItemState);
    }   

    private function viewSkin(state:String):void
    {  	
    	var newSkinClass:Class = Class(getStyle(state));
    	var newSkin:IFlexDisplayObject;
    	var stateName:String = "";
    	    	
    	if (!newSkinClass)
    	{
    		// Try the default skin
    		newSkinClass = Class(getStyle(skinName)); 		
    		    	
    		if (state == "itemDownSkin")
    			stateName = "down";
    		else if (state == "itemOverSkin")
    			stateName = "over";
    		else if (state == "itemUpSkin")
    			stateName = "up";
    		
    		// If we are using the default skin, then 
    		if (defaultSkinUsesStates)
    			state = skinName;
    		
     		if (!checkedDefaultSkin && newSkinClass)
    		{
	    		newSkin = IFlexDisplayObject(new newSkinClass());
	    		// Check if the skin class is a state client or a programmatic skin
	    		if (!(newSkin is IProgrammaticSkin) && newSkin is IStateClient)
	    		{
	    			defaultSkinUsesStates = true;
	    			state = skinName;
	    		}
	    		
	    		if (newSkin)
	    		{
		    		checkedDefaultSkin = true;
		    	}
    		}
    	}
    	
      	newSkin = IFlexDisplayObject(getChildByName(state));

        if (!newSkin)
        {
            if (newSkinClass)
            {
                newSkin = new newSkinClass();

                DisplayObject(newSkin).name = state;

                if (newSkin is ISimpleStyleClient)
                    ISimpleStyleClient(newSkin).styleName = this;

                addChildAt(DisplayObject(newSkin), 0);
            }
        }

        newSkin.setActualSize(unscaledWidth, unscaledHeight);

        if (currentSkin)
            currentSkin.visible = false;

        if (newSkin)
            newSkin.visible = true;

        currentSkin = newSkin;
        
        // Update the state of the skin if it accepts states and it implements the IStateClient interface.
		if (defaultSkinUsesStates && currentSkin is IStateClient)
		{
			IStateClient(currentSkin).currentState = stateName;
		}
    }

	private static function calcDerivedStyles(themeColor:uint,  fillColor0:uint, fillColor1:uint):Object
	{
		var key:String = HaloColors.getCacheKey(themeColor,fillColor0, fillColor1);
				
		if (!cache[key])
		{
			var o:Object = cache[key] = {};
			
			// Cross-component styles.
			HaloColors.addHaloColors(o, themeColor, fillColor0, fillColor1);
		}
		
		return cache[key];
	}

	/**
	 *  @private
	 */
	override protected function updateDisplayList(w:Number, h:Number):void
	{
		super.updateDisplayList(w, h);

		if (!getStyle("translucent"))
			drawHaloRect(w, h);
		else
			drawTranslucentHaloRect(w, h);
	}

	/**
	 *  @private
	 */
	private function drawHaloRect(w:Number, h:Number):void
	{
		var fillAlphas:Array = getStyle("fillAlphas");
		var fillColors:Array = getStyle("fillColors");
		var highlightAlphas:Array = getStyle("highlightAlphas");				
		var themeColor:uint = getStyle("themeColor");

		var themeColorDrk1:Number =
			ColorUtil.adjustBrightness2(themeColor, -25);

		// Derivative styles.
		var derStyles:Object = calcDerivedStyles(themeColor, fillColors[0], fillColors[1]);
												 
		graphics.clear();

		switch (name)
		{
			case "itemUpSkin": // up/disabled
			{
				// invisible hit area
				drawRoundRect(
					x, y, w, h, 0,
					0xFFFFFF, 0);
				break;
			}

			case "itemDownSkin":
			{
				// face
				drawRoundRect(
					x + 1, y + 1, w - 2, h - 2, 0,
					[ derStyles.fillColorPress1, derStyles.fillColorPress2], 1,
					verticalGradientMatrix(0, 0, w, h )); 
									
				// highlight
				drawRoundRect(
					x + 1, y + 1, w - 2, h - 2 / 2, 0,
					[ 0xFFFFFF, 0xFFFFFF ], highlightAlphas,
					verticalGradientMatrix(0, 0, w - 2, h - 2));

				break;
			}

			case "itemOverSkin":
			{
				var overFillColors:Array;
				if (fillColors.length > 2)
					overFillColors = [ fillColors[2], fillColors[3] ];
				else
					overFillColors = [ fillColors[0], fillColors[1] ];

				var overFillAlphas:Array;
				if (fillAlphas.length > 2)
					overFillAlphas = [ fillAlphas[2], fillAlphas[3] ];
  				else
					overFillAlphas = [ fillAlphas[0], fillAlphas[1] ];

				// face
				drawRoundRect(
					x + 1, y + 1, w - 2, h - 2, 0,
					overFillColors, overFillAlphas,
					verticalGradientMatrix(0, 0, w, h )); 

				// highlight
				drawRoundRect(
					x + 1, y + 1, w - 2, h - 2 / 2, 0,
					[ 0xFFFFFF, 0xFFFFFF ], highlightAlphas,
					verticalGradientMatrix(0, 0, w - 2, h - 2));
				
				break;
			}
		}

		filters = [ new BlurFilter(2, 0) ];
	}

public static function addHaloColors(colors:Object,  themeColor:uint,  fillColor0:uint, fillColor1:uint):void
{
	var key:String = getCacheKey(themeColor, fillColor0, fillColor1); 
	var o:Object = cache[key];
	
	if (!o)
	{
		o = cache[key] = {};
		
		// Cross-component styles
		o.themeColLgt = ColorUtil.adjustBrightness(themeColor, 100);
		o.themeColDrk1 = ColorUtil.adjustBrightness(themeColor, -75);
		o.themeColDrk2 = ColorUtil.adjustBrightness(themeColor, -25);
		o.fillColorBright1 = ColorUtil.adjustBrightness2(fillColor0, 15);
		o.fillColorBright2 = ColorUtil.adjustBrightness2(fillColor1, 15);
		o.fillColorPress1 = ColorUtil.adjustBrightness2(themeColor, 85);
		o.fillColorPress2 = ColorUtil.adjustBrightness2(themeColor, 60);
		o.bevelHighlight1 = ColorUtil.adjustBrightness2(fillColor0, 40);
		o.bevelHighlight2 = ColorUtil.adjustBrightness2(fillColor1, 40);
	}
	
	colors.themeColLgt = o.themeColLgt;
	colors.themeColDrk1 = o.themeColDrk1;
	colors.themeColDrk2 = o.themeColDrk2;
	colors.fillColorBright1 = o.fillColorBright1;
	colors.fillColorBright2 = o.fillColorBright2;
	colors.fillColorPress1 = o.fillColorPress1;
	colors.fillColorPress2 = o.fillColorPress2;
	colors.bevelHighlight1 = o.bevelHighlight1;
	colors.bevelHighlight2 = o.bevelHighlight2;
}

MenuBar { 
	font-weight:bold; 
	color:#FFFFFF;
	fill-colors:#0D0A92, #1B16F4, #37920A, #59EB12;
	fill-alphas:1.0,1.0;
	itemSkin: ClassReference("skins.MyActivatorSkin");
}

MenuBarTest.zip

<?xml version="1.0" encoding="utf-8"?>
<!--
	간단한 Adobe AIR 웹브라우져
	제작 : 지용호 
-->
<s:WindowedApplication xmlns:fx="http://ns.adobe.com/mxml/2009" 
					   xmlns:s="library://ns.adobe.com/flex/spark" 
					   xmlns:mx="library://ns.adobe.com/flex/halo"
					   backgroundFrameRate="0.01"
					   windowComplete="windowedapplication1_windowCompleteHandler(event)">
	<fx:Script>
		<![CDATA[
			import flash.events.Event;
			import flash.net.URLRequest;
			import flash.net.navigateToURL;
			
			import mx.events.AIREvent;

			private function windowedapplication1_windowCompleteHandler(event:AIREvent):void {
				nativeWindow.x = 0;
				nativeWindow.y = 0;
				width = 1280;
				height = 900;
				//browser.htmlLoader.navigateInSystemBrowser = true;
			}
			private function linkClickHandler(o:Object):void {
				navigateToURL( new URLRequest(o.currentTarget.href), "blank" );
			}
			private function browser_locationChangeHandler(event:Event):void {
				trace( "browser_locationChangeHandler" );
				tiAddress.text = browser.location;
				btnBack.enabled = browser.historyPosition==0?false:true;
				btnNext.enabled= (browser.historyPosition < browser.historyLength-1)?true:false;
			}
			private function onGoHandler(event:Event):void {
				browser.location = tiAddress.text;
			}
			private function browser_completeHandler(event:Event):void
			{
				trace( "browser_completeHandler" );
				tiAddress.text = browser.location;
				var dom:Object = HTML(event.currentTarget).domWindow.document;
				var links:Object = dom.getElementsByTagName("a");
				for( var i:Number = 0; i < links.length; i++ ) {
					if( links[i].target.toLowerCase() == "_blank" || links[i].target.toLowerCase() == "_new" ) {
						links[i].onclick = linkClickHandler;
					}
				}
			}
		]]>
	</fx:Script>
	<s:VGroup width="100%" height="100%">
		<s:HGroup verticalAlign="middle" paddingLeft="10" paddingRight="10" paddingTop="5" paddingBottom="5">
			<s:Button id="btnBack" label="뒤로" click="browser.historyBack()"/>
			<s:Button id="btnNext" label="앞으로" click="browser.historyForward()"/>
			<s:Button label="새로고침" click="browser.reload()"/>
			<s:Label text="주소 : "/>
			<s:TextInput id="tiAddress" width="400" enter="onGoHandler(event)"/>
			<s:Button label="가기" click="onGoHandler(event)"/>
		</s:HGroup>
		<s:HGroup verticalAlign="middle" paddingLeft="10" paddingRight="10" paddingTop="5" paddingBottom="5">
			<s:Button label="지돌스타 블로그" click="browser.location='http://blog.jidolstar.com'"/>
			<s:Button label="위콘 블로그" click="browser.location='http://weconize.com'"/>
			<s:Button label="천문노트" click="browser.location='http://astronote.org'"/>
			<s:Button label="Adobe RIA" click="browser.location='http://adoberia.co.kr'"/>
			<s:Button label="Adobe Labs" click="browser.location='http://labs.adobe.com'"/>
			<s:Button label="Adobe Development Center" click="browser.location='http://www.adobe.com/devnet/'"/>
		</s:HGroup>
		<!-- http://labs.adobe.com/wiki/index.php/Apollo:Articles:Using_HTML_in_Flex-based_Apollo_Applications -->
		<mx:HTML id="browser" width="100%" height="100%" 
				 location="http://blog.jidolstar.com"
				 complete="browser_completeHandler(event)"
				 locationChange="browser_locationChangeHandler(event)"/>
	</s:VGroup>
</s:WindowedApplication>

/**
*  Constructor.
*  
*  @langversion 3.0
*  @playerversion AIR 1.5
*  @productversion Flex 4
*/
public function WindowedApplication()
{
	super();

	addEventListener(MouseEvent.MOUSE_DOWN, mouseDownHandler);
	addEventListener(FlexEvent.PREINITIALIZE, preinitializeHandler);
	addEventListener(FlexEvent.UPDATE_COMPLETE, updateComplete_handler);
	addEventListener(FlexEvent.CREATION_COMPLETE, creationCompleteHandler);

	var nativeApplication:NativeApplication = NativeApplication.nativeApplication;
	nativeApplication.addEventListener(Event.ACTIVATE, nativeApplication_activateHandler);
	nativeApplication.addEventListener(Event.DEACTIVATE, nativeApplication_deactivateHandler);
	nativeApplication.addEventListener(Event.NETWORK_CHANGE, dispatchEvent);

	nativeApplication.addEventListener(InvokeEvent.INVOKE, nativeApplication_invokeHandler);
	initialInvokes = new Array();

	//Force DragManager to instantiate so that it can handle drags from
	//outside the app.
	DragManager.isDragging;
}

/**
*  @private
*  Storage for the backgroundFrameRate property.
*/
private var _backgroundFrameRate:Number = 1;

/**
*  Specifies the frame rate to use when the application is inactive.
*  When set to -1, no background frame rate throttling occurs.
*
*  @default 1
*  
*  @langversion 3.0
*  @playerversion AIR 1.5
*  @productversion Flex 4
*/
public function get backgroundFrameRate():Number
{
	return _backgroundFrameRate;
}

/**
*  @private
*/ 
public function set backgroundFrameRate(frameRate:Number):void
{
	_backgroundFrameRate = frameRate;
}

/**
*  @private
*/
private function nativeApplication_activateHandler(event:Event):void
{
	dispatchEvent(new AIREvent(AIREvent.APPLICATION_ACTIVATE));

	// Restore throttled framerate if appropriate when application is activated.
	if (prevActiveFrameRate >= 0 && stage)
	{
	    stage.frameRate = prevActiveFrameRate;  
	    prevActiveFrameRate = -1;
	}
}

/**
*  @private
*/
private function nativeApplication_deactivateHandler(event:Event):void
{
	dispatchEvent(new AIREvent(AIREvent.APPLICATION_DEACTIVATE));

	// Throttle framerate if appropriate when application is deactivated.
	// Ensure we've received an updateComplete on the chance our layout
	// manager is using phased instantiation (we don't wish to store a
	// maxed out (1000fps) framerate).
	if ((_backgroundFrameRate >= 0) && (ucCount > 0) && stage)
	{
	    prevActiveFrameRate = stage.frameRate;
	    stage.frameRate = _backgroundFrameRate; 
	}
}

아래 소스는 다음 링크에서 다운로드 받으셔도 됩니다.

CPUReducing.zip

초급
Framerate를 줄일때의 시점을 선택하는데 가장 쉽고 유용한 방법은 NativeApplication에서 Event.ACTIVATE 와 Event.DEACTIVATE 이벤트를 사용하는 것이다. AIR로 만들어진 빈윈도우를 선택해서 사용할때 CPU사용율이 1.8%라면 다른 윈도우를 선택해 그 윈도우의 CPU 사용율이 0.4%까지 떨여졌다고 한다. 또한 framerate를 0.01로 지정하면 0.2%까지 떨어진다고 한다. 이에 대한 예제는 다음과 같다. 예제가 이해하기 쉬우므로 따로 설명하지 않겠다.

package {
	import flash.desktop.NativeApplication;
	import flash.display.NativeWindow;
	import flash.display.NativeWindowInitOptions;
	import flash.display.NativeWindowType;
	import flash.display.Sprite;
	import flash.display.StageAlign;
	import flash.display.StageScaleMode;
	import flash.events.Event;
	import flash.text.TextField;
	import flash.text.TextFieldAutoSize;
	import flash.utils.getTimer;
	
	/**
	 * CPU 사용 줄이기 예제 1 
	 * @author Yongho, Ji
	 * @since 2009.12.1
	 * @see http://blog.jidolstar.com/622
	 */ 
	public class Novice extends Sprite {
		private var __isActive:Boolean = false;
		private var __window:NativeWindow;
		private var __textField:TextField;
		public function Novice() {
			__init();
			var options:NativeWindowInitOptions = new NativeWindowInitOptions();
			options.type = NativeWindowType.UTILITY;
			
			__window = new NativeWindow(options);
			__window.width = 200;
			__window.height = 200;
			__window.title = "Novice";
			
			__textField = new TextField();
			__textField.autoSize = TextFieldAutoSize.LEFT;
			__textField.text = "";
			
			__window.stage.scaleMode = StageScaleMode.NO_SCALE;
			__window.stage.align = StageAlign.TOP_LEFT;
			
			__window.stage.addChild(__textField);
			__window.activate();
			__window.addEventListener(Event.CLOSING,__onClosing);
		}
		private function __init():void {
			NativeApplication.nativeApplication.addEventListener(Event.ACTIVATE, __onActive );
			NativeApplication.nativeApplication.addEventListener(Event.DEACTIVATE, __onDeactive );
			stage.addEventListener(Event.ENTER_FRAME,__onEnterFrame);
		}
		private function __onActive($event:Event):void {
			stage.frameRate = 50;
			__isActive = true;
		}
		private function __onDeactive($event:Event):void {
			stage.frameRate = 1;
			__isActive = false;
		}
		private function __onEnterFrame($event:Event):void {
			__textField.text =  "active:" + __isActive + " " + getTimer();
		}
		private function __onClosing($event:Event):void {
			NativeApplication.nativeApplication.exit();
		}
	}
}

package {
	import flash.desktop.NativeApplication;
	import flash.display.NativeWindow;
	import flash.display.NativeWindowInitOptions;
	import flash.display.NativeWindowType;
	import flash.display.Sprite;
	import flash.display.StageAlign;
	import flash.display.StageScaleMode;
	import flash.events.Event;
	import flash.events.MouseEvent;
	import flash.text.TextField;
	import flash.text.TextFieldAutoSize;
	import flash.utils.getTimer;
	/**
	 * CPU 사용 줄이기 예제 2 
	 * @author Yongho, Ji
	 * @since 2009.12.1
	 * @see http://blog.jidolstar.com/622
	 */ 
	public class Intermediate extends Sprite {
		private static const ACTIVE:int = 50;
		private static const INACTIVE:int = 1;
		private var __isActive:Boolean = false;
		private var __isScrolling:Boolean = false;
		private var __buffer:int;

		private var __window:NativeWindow;
		public function Intermediate() {
			__init();
			var options:NativeWindowInitOptions = new NativeWindowInitOptions();
			options.type = NativeWindowType.UTILITY;
			
			__window = new NativeWindow(options);
			__window.width = 200;
			__window.height = 200;
			__window.title = "Intermediate";
			
			var textField:TextField = new TextField();
			textField.y = 20;
			textField.width = 195;
			textField.height = 175;
			textField.multiline = true;
			textField.wordWrap = true;
			textField.border = true;
			textField.borderColor = 0xff0000;
			textField.text = "Adobe AIR는 다양한 OS(Windows, Mac, Linux)에 구동될 수 있는 애플리케이션을 만드는데 사용하는 일종의 Flash Platfom기술이다. Flash ActionScript 3.0이나 Ajax만으로도 AIR 애플리케이션을 만들 수 있기 때문에 기존에 웹개발자들이 다른 언어를 배우지 않고 일반 데스크탑용 애플리케이션을 만드는데 있어서 접근성이 좋다. 앞으로 AIR는 데스크탑뿐 아니라 모바일등과 같은 다양한 기기에도 적용될 예정이다.하지만 원천적으로 데스크탑용 애플리케이션과 비교해 그 적용범위가 아직까지 많은 부분 부족하고 복잡한 UI를 다루는데 있어서 성능문제가 걸릴 수 있다. 적용되는 범위는 AIR 2.0 Beta 버전이 오픈된 것을 볼 수 있었듯이 계속 발전해나갈 것이다. 또한 성능면에서도 마찬가지 일 것이다. 그래도 성능면에 있어서 개발자가 조금만 신경을 쓴다면 어떤 부분에 있어서 획기적으로 AIR 애플리케이션의 성능을 향상시킬 수 있다. 일전에 Reducing CPU usage in Adobe AIR라는 글을 보았다. 여기서는 매우 단순하고 쉬운 방법으로 framerate를 줄임으로서 CPU 사용율을 현격히 줄이는 방법을 소개하고 있다. ";

			__window.stage.scaleMode = StageScaleMode.NO_SCALE;
			__window.stage.align = StageAlign.TOP_LEFT;
			
			__window.stage.addChild(textField);
			__window.activate();
			__window.addEventListener(Event.CLOSING,__onClosing);
		}
		private function __init():void {
			NativeApplication.nativeApplication.addEventListener(Event.ACTIVATE, __onActive );
			NativeApplication.nativeApplication.addEventListener(Event.DEACTIVATE, __onDeactive );
			stage.addEventListener(MouseEvent.MOUSE_WHEEL, __onMouseWheel, true);
		}
		private function __onActive($event:Event):void {
			stage.frameRate = ACTIVE;
			__isActive = true;
			trace( "active" );
		}
		private function __onDeactive($event:Event):void {
			stage.frameRate = INACTIVE;
			__isActive = false;
			trace( "deactive" );
		}
		private function __onMouseWheel($event:MouseEvent):void {
			if( !__isActive ) {
				if ( !__isScrolling ) {
					stage.addEventListener(Event.ENTER_FRAME, __onEnterFrame, true);
				}
				stage.frameRate = ACTIVE;
				__isScrolling = true;
				__buffer = getTimer()+500;
			}
		}
		private function __onEnterFrame($event:Event):void {
			if( __buffer < getTimer() ) {
				stage.frameRate = INACTIVE;
				__isScrolling = false;
			}
		}
		private function __onClosing($event:Event):void {
			NativeApplication.nativeApplication.exit();
		}
	}
}

package {
	import flash.desktop.NativeApplication;
	import flash.display.NativeWindow;
	import flash.display.NativeWindowInitOptions;
	import flash.display.NativeWindowType;
	import flash.display.Shape;
	import flash.display.SimpleButton;
	import flash.display.Sprite;
	import flash.display.StageAlign;
	import flash.display.StageScaleMode;
	import flash.events.Event;
	import flash.events.MouseEvent;
	import flash.filters.BevelFilter;
	import flash.text.TextField;
	import flash.text.TextFormat;
	import flash.utils.getTimer;
	import flash.utils.setTimeout;
	/**
	 * CPU 사용 줄이기 예제 3 
	 * @author Yongho, Ji
	 * @since 2009.12.1
	 * @see http://blog.jidolstar.com/622
	 */ 
	public class Expert extends Sprite {
		public static const ANIMATING:int = 50;
		public static const ACTIVE:int = 24;
		public static const INACTIVE_VISIBLE:int = 5;
		public static const INACTIVE_INVISIBLE:int = 1;
		
		private var __isActive:Boolean = false;
		private var __isAnimating:Boolean = false;
		private var __window:NativeWindow;
		private var __buffer:int;
		
		public function Expert() {
			__init();
			var options:NativeWindowInitOptions = new NativeWindowInitOptions();
			options.type = NativeWindowType.UTILITY;
			
			__window = new NativeWindow(options);
			__window.width = 200;
			__window.height = 200;
			__window.title = "Expert";
			
			__window.stage.scaleMode = StageScaleMode.NO_SCALE;
			__window.stage.align = StageAlign.TOP_LEFT;
			
			//창을 감추기 버튼 
			var buttonSkin:Sprite = new Sprite;
			buttonSkin.graphics.beginFill( 0xff0000, 1.0 );
			buttonSkin.graphics.drawRect(0,0,100,50);
			buttonSkin.graphics.endFill();
			buttonSkin.filters = [new BevelFilter()];
			var textFormat:TextFormat = new TextFormat();
			textFormat.color = 0xffffff;
			textFormat.align = "center";
			var textField:TextField = new TextField();
			textField.defaultTextFormat = textFormat;
			textField.text = "창을 감추기(1초후에 나타남)";
			textField.width = 100;
			textField.multiline = true;
			textField.wordWrap = true;
			textField.y = buttonSkin.height/2 - textField.textHeight/2; 
			buttonSkin.addChild( textField );
			var button:SimpleButton = new SimpleButton(buttonSkin,buttonSkin,buttonSkin,buttonSkin);
			button.addEventListener(MouseEvent.CLICK, __onHide );
			__window.stage.addChild( button );
			
			//Animation 동작 시키기 버튼 
			buttonSkin = new Sprite;
			buttonSkin.graphics.beginFill( 0x0000ff, 1.0 );
			buttonSkin.graphics.drawRect(0,0,100,50);
			buttonSkin.graphics.endFill();
			buttonSkin.filters = [new BevelFilter()];
			textFormat = new TextFormat();
			textFormat.color = 0xffffff;
			textFormat.align = "center";
			textField = new TextField();
			textField.defaultTextFormat = textFormat;
			textField.text = "동작시키기(1 second)";
			textField.width = 100;
			textField.multiline = true;
			textField.wordWrap = true;
			textField.y = buttonSkin.height/2 - textField.textHeight/2; 
			buttonSkin.addChild( textField );
			button= new SimpleButton(buttonSkin,buttonSkin,buttonSkin,buttonSkin);
			button.y = 52;
			button.addEventListener(MouseEvent.CLICK, __onAnimate );
			__window.stage.addChild( button );			
						
			__window.activate();
			__window.addEventListener(Event.CLOSING,__onClosing);
		}
		private function __init():void {
			NativeApplication.nativeApplication.addEventListener(Event.ACTIVATE, __onActive );
			NativeApplication.nativeApplication.addEventListener(Event.DEACTIVATE, __onDeactive );
		}
		private function setFrameRate( frameRate:Number ):void {
			stage.frameRate = frameRate;
			trace( frameRate );
		}
		private function animate($duration:int = 1000):void {
			trace( "동작시작");
			setFrameRate( 50 );
			__buffer = getTimer() + $duration;
			if(!__isAnimating) {
				stage.addEventListener(Event.ENTER_FRAME,__onEnterFrame);
			}
		}
		private function active():void {
			if(!__isAnimating) {
				setFrameRate( ACTIVE );	
			} 
			trace( "active " );
		}
		private function deactive():void {
			if (!__isAnimating) {
				setFrameRate( (__window.visible) ? INACTIVE_VISIBLE : INACTIVE_INVISIBLE );
			}
			trace( "deactive " );
		}
		private function show():void {
			__window.visible = true;
			active();
		}
		private function hide():void {
			__window.visible = false;	
			deactive();
		}
		private function __onActive($event:Event):void {
			__isActive = true;
			active();
		}
		private function __onDeactive($event:Event):void {
			__isActive = false;
			deactive();
		}
		private function __onEnterFrame($event:Event):void {
			if( __buffer < getTimer() ) {
				trace( "동작끝");
				stage.removeEventListener(Event.ENTER_FRAME,__onEnterFrame);
				__isAnimating = false;
				if( __isActive ) {
					active();
				} else {
					deactive();
				}
			}
		}
		private function __onHide($event:MouseEvent):void {
			hide();
			setTimeout(show,1000);
		}
		private function __onAnimate($event:MouseEvent):void {
			animate( 1000 );
		}
		private function __onClosing($event:Event):void {
			NativeApplication.nativeApplication.exit();
		}
	}
}

[Listen(obj="this.closeButton", event="click")]
public function closeClickHandler(event:MouseEvent) {...}

커스텀 메타데이타를 사용하는 방법
커스텀 메타데이타를 사용하는 방법은 3단계로 이뤄진다.

1. 컴파일러 구성
Flex 프로젝트 컴파일 옵션으로 "-keep-as3-metadata+=Meta1, Meta2" 를 삽입한다. 만약 라이브러리 프로젝트에서 한다면 거기에 이 옵션을 사용하면 이 라이브러리 프로젝트를 참조하는 다른 프로젝트에 따로 줄필요는 없다.

2. metadata를 작성

package
{
    [Meta2(param1 = "param 1 value")]
    public class TestClass
    {

        [Meta1(param1 = "param 1 value", param2 = "param 2 value")]
        public var test1:String;
        
        
        [Meta2(paramA = "param 1 value", paramB = "param 2 value")]
        public function get test2():String
        {
            return null;
        }
        
        public function set test2(val:String):void
        {
        }

        [Meta1(param1 = "param 1 value")]
        public function someMethod():void
        {
        };

    }
}

<type name="TestClass" base="Class" isDynamic="true" isFinal="true" isStatic="true">
  <extendsClass type="Class"/>
  <extendsClass type="Object"/>
  <accessor name="prototype" access="readonly" type="*" declaredBy="Class"/>
  <factory type="TestClass">

    <metadata name="Meta2">
      <arg key="param1" value="param 1 value"/>
    </metadata>

    <extendsClass type="Object"/>

    <method name="someMethod" declaredBy="TestClass" returnType="void">
      <metadata name="Meta1">
        <arg key="param1" value="param 1 value"/>
      </metadata>
    </method>

    <variable name="test1" type="String">
      <metadata name="Meta1">
        <arg key="param1" value="param 1 value"/>
        <arg key="param2" value="param 2 value"/>
      </metadata>
    </variable>

    <accessor name="test2" access="readwrite" type="String" declaredBy="TestClass">
      <metadata name="Meta2">
        <arg key="paramA" value="param 1 value"/>
        <arg key="paramB" value="param 2 value"/>
      </metadata>
    </accessor>

  </factory>
</type>

var testClass:TestClass = new TestClass();
var xml:XML = describeType(testClass);
trace(xml.metadata.(@name==Meta2).arg.(@key==param1).@value);

package
{
	[Bindable]
	[Table(name="contact")]
	public class Contact
	{
		[Id]
		[Column(name="contact_id")]
		public var contactId:int;

		[Column(name="first_name")]
		public var firstName:String;

		[Column(name="last_name")]
		public var lastName:String;
		public var address:String;
		public var city:String;
		public var state:String;
		public var zip:String;
		public var phone:String;
		public var email:String;
	}
}

var contact:Contact = new Contact();
contact.firstName = "Christophe";
contact.lastName = "Coenraets";
contact.email = "ccoenrae@adob.com";
entityManager.save(contact);

contact.firstName = "Chris";
entityManager.save(contact);

entityManager.remove(contact);

접기

air_orm.zip

접기

Flash Platform 개발자 분들에게 반가운 소식이 있습니다. AIR 2.0 Beta와 Flash Player 10.1 Prelease 버전이 공개되었습니다. 이제 Adobe Labs(http://labs.adobe.com/)에서 직접 다운로드 받을 수 있습니다.

• AIR 2.0 Beta : http://labs.adobe.com/technologies/air2/
• Flash Player 10.1 : http://labs.adobe.com/technologies/flashplayer10/
  

Adobe AIR 2.0 beta

AIR 2.0은 다음과 같은 새로운 feature들이 추가되었습니다.(영어 압박? 그럼 : http://blog.chanik.com/entry/AIR-20-Beta-릴리즈 )

• Support for the detection of mass storage devices.
• Advanced networking capabilities like secure sockets, UDP support, and the ability to listen on sockets.
• Support for native code integration.
• The ability to open a file with its default application.
• Multi-touch and gesture support.
• New APIs for access to raw microphone data.
• Webkit update with HTML5/CSS3 support.
• Global error handling.
• Improved cross-platform printing
• Improved security and support for enterprise and government standards.

AIR 2.0에 대해서 자세한 설명 다음 글들을 참고하세요. 

• Introducing Adobe AIR 2 beta 
• AIR 2:Release Notes  
• Learn to Use Adobe AIR 2 Beta

AIR 2.0으로 개발테스트 하시려면 다음과 같이 합니다. 윈도우, Flash Builder 4 beta 2 환경을 가정하고 설명드립니다.

1. 만약 Flash Builder를 설치 안했다면 다음 링크를 통해 받으세요.
   
   http://www.adoberia.co.kr/pds/down.html?src=text&kw=000026
   
2. SDK와 Runtime을 다운로드 받습니다.
3. 다운받은 Runtime을 실행해 설치합니다.
4. SDK는 압축을 풀고 그안에 있는 내용을 Flash builder가 설치된 sdks/4.0.0과 sdks/3.4.1 폴더에 각각 덮어씌웁니다. 제 경우는 C:\Program Files\Adobe\Adobe Flash Builder Plug-in Beta 2\sdks\4.0.0
5. Flash Builder를 실행합니다.
   Windows>Preferences에 들어가 Flash Builder > Installed Flex SDKs를 확인해보세요.
   
   
6. Learn to Use Adobe AIR 2 Beta에 들어가 관련 내용을 학습합니다.
7. Adobe AIR 2 Sample Applications에 들어가 Sample을 받아보고 실제 Flash Builder에서 작업해봅시다. (해당작업화면을 이미지 캡쳐하고 이런거 너무 힘들어서요. 그냥 말로 주절주절 써봅니다.)
   저는 일단 수많은 예제들중에 Microphone 예제의 소스를 다운로드 받았습니다.
   Flash Builder에서 Flex Project를 생성합니다. 물론 Application Type은 Desktop으로 설정해야겠죠? 예제를 다운받아 사용하므로 프로젝트 이름은 예제 소스 압축을 풀어보면 메인소스의 이름을 선택해주면 됩니다. 저의 경우 MicrophoneExamples군요. 프로젝트를 생성했으면 그 다음으로 Flash Builder에서 방금 생성한 프로젝트를 선택한 상태에서 마우스 오른쪽 버튼을 눌러 Import로 들어갑니다. 창이 뜨면 General > Archive File을 선택하고 다음 버튼을 누릅니다. Browse...버튼을 눌러 다운받은 소스압축파일을 선택합니다. 그리고 Finish하세요. Overwrite할거냐 물으면 Yes To All 을 선택하시면 됩니다. 초반에 sdk 에러가 뜰겁니다. 원본 소스의 sdk 설정이 달라서 그러는데요. 이것을 해결하기 위해 프로젝트명을 선택한후 마우스오른쪽 버튼을 눌러 Properties로 들어가 Flex Compiler를 선택한 다음 Use a specific SDK를 Flex 3.4로 선택해주시면 됩니다. 4.0이 아닌 이유는 예제 소스가 mx:WindowedApplication으로 만든 것으로보아 Flex 3.4 기반으로 만들어졌기 때문입니다. 다른 예제가 s:WindowedApplication으로 만들어져 있다면 Flex 4.0을 선택하세요. 다 끝났습니다. 이제 실행해보세요.
   
   
   
   
   앗... 제 데톱에 마이크가 없군요... ㅡㅡ; 아무튼 이렇게 하면 됩니다. Sample에는 Flex뿐 아니라 Ajax, Flash용도 있으니 잘 활용하시면 학습하는데 도움이 될겁니다.

Flash Player 10.1 Prelease

Flash Player 10.1의 가장 큰 특징은 바로 모바일 지원입니다. 제 블로그에서 앞서 설명했지만 Flash Player 10.1은 오픈소스프로젝트를 통해 탄생된 결과물입니다. 데스크탑 뿐아니라 다양한 기기에서도 Adobe Flash Platform 기술이 적용될 수 있도록 Flash Player 10.1을 만든겁니다. 이는 모바일과 같이 저급(?) 하드웨어 기반에서 항상 이슈가 되어 왔던 메모리, 전력소비, 속도, 하드웨어가속등의 문제를 해결한 Flash Player를 만들었다는 것을 의미합니다. 이외에도 차세대 모바일에 걸맞는 몇가지 기능(멀티터치등)을 구현할 수 있는 API도 추가되었죠. 또한 H.264 비디오도 지원해줍니다.

Flash Player 10.1에 대해서 더욱 자세히 알고 싶다면 Flash Player 10.1 Beta Release Notes를 참고하시면 될 것 같습니다.

Flash Player 10.1 기반의 프로그램을 개발하고 싶다면 Flash Player 10.1 플러그인을 자신의 컴퓨터에 먼저 설치한뒤 Player Global SWC를 다운받아 개발하면 됩니다. 일련의 절차를 간단하게 설명드립니다.

참고로 Flash Player 10.1은 정식 배포버전이 아닙니다. 테스트 목적으로 하시고 실제 배포는 하지 마세요.

Flash Player 10.1 플러그인을 http://labs.adobe.com/downloads/flashplayer10.html 에서 다운로드 받습니다. 기존에 설치된 Flash Player는 삭제를 하시고 설치하세요. 윈도우의 경우 파이어폭스와 모질라 계열이라면 Download plug-in for Windows (EXE, 2.2 MB)를 받고 IE라면 Download active-x for Windows (EXE, 2.2 MB)를 다운로드 받으세요. 아쉽게도 개발자를 위한 디버그 버전은 아직 없는 것 같습니다.

Flash Player 10.1 기반 개발을 위해 해당 API로 개발할 수 있도록 지원해주는 SWC를 다운로드를 같은 페이지에서 받을 수 있습니다. 다운받아 압축을 풀면 playerglobal.swc가 있습니다. 이것을 자신의 프로젝트에 포함하여 개발하면 됩니다. 함께 포함된 readme.txt파일을 보면 사용하는 방법이 잘 나와 있는데 여기서도 간단히 설명해 드리죠. (단, Flash Builder 4 beta 2 기준입니다.)

1. 만약 Flash Builder를 설치 안했다면 다음 링크를 통해 받으세요.
   
   http://www.adoberia.co.kr/pds/down.html?src=text&kw=000026
   
2. 새로운 애플리케이션 프로젝트를 만듭니다.
3. playerglobal.swc를 playerglobal10.1.swf로 이름을 바꾸고 만들어진 프로젝트의 libs폴더에 복사합니다. libs폴더에 복사하면 자동으로 Referenced Libraries로 설정됩니다. (여기서 이름을 바꾼 이유는 다음 내용을 설정할 때 playerglobal.swc의 Link Type을 수정못하도록 Flash Builder가 만들어져 있기 때문입니다.)
4. 프로젝트명을 선택후 마우스 오른쪽 버튼을 눌러 properties를 선택한 뒤 Flex Builder Path를 선택합니다. 그런 다음 Library path 탭을 선택한뒤 libs 폴더를 열어 Link Type을 External로 바꿉니다. 그런 다음 Flex 4.0 를 열어 기존 playerglobal.swc는 삭제합니다. Link type이 External이라는 것은 컴파일시 사용한 클래스를 빼놓는다는 뜻입니다. 어짜피 playerglobal.swc에 정의된 클래스는 이미 Flash player 10.1에서 지원해주기 때문에 굳이 swf안에 포함할 필요가 없기 때문이지요.
5. Flash Player 10.1을 요구하는 HTML이 되도록 만들어주기 위해 Properties 창에서 Flex Compiler를 선택합니다. Adobe Flash Player options에서 Use a specific version을 10.1.0으로 바꾸거나 Additional compiler arguments에 -target-player=10.1.0 을 추가합니다.

이로써 Flash Player 10.1 에서 돌아가는 Flash 애플리케이션을 만들때 환경 구축을 모두 완료했습니다.

아래처럼 Flash Player 10.1 API인 TouchEvent, TransformGestureEvent 등을 사용할 수 있게 되었습니다.

• Flash Player 10.1 데모 및 인터뷰 
• Introducing Adobe Flash Player 10.1 public prerelease 
• Flash Player 10.1 hardware acceleration for video and graphics 

앞으로 정식버전이 배포되고 Flash CS5도 나오게 되면 아이폰 및 다양한 기기에서 동작하는 재미있는 애플리케이션들을 만들 수 있게 될 것입니다. 

Flash Platform 개발자들이여.. 향후 10년 밥벌이 벌었습니다. ㅋㅋㅋ


글쓴이 : 지돌스타(http://blog.jidolstar.com/617)
 

[Embed(source='C:/WINDOWS/Fonts/ARIAL.TTF', fontName = "MyFont", mimeType = "application/x-font-truetype")]
private var font:Class;

package {
	import flash.display.Sprite;
	import flash.text.TextField;
	import flash.text.TextFormat;
	import flash.text.TextFieldAutoSize;
	import flash.text.AntiAliasType;
	[SWF(width = "500", height = "240", backgroundColor = "#FFFFFF", framerate = "24")]
	public class FontTest extends Sprite {
		[Embed(source='C:/WINDOWS/Fonts/ARIAL.TTF', embedAsCFF="false", fontName = "MyFont", mimeType = "application/x-font-truetype")]
		private var font:Class;
		public function FontTest() {
			var format:TextFormat = new TextFormat();
			format.font = "MyFont";
			format.size = 30;
			format.color = 0x000000;
			var label:TextField = new TextField();
			label.embedFonts = true;
			label.autoSize = TextFieldAutoSize.LEFT;
			label.antiAliasType = AntiAliasType.ADVANCED;
			label.defaultTextFormat = format;
			label.text = "blog.jidolstar.com";
			addChild(label);
			label.rotation = 5;
		}
	}
}

cff.pdf

이 실험은 Flash Builder 4 Beta 2에서 테스트 했으며 아래 링크로부터 Flash Builder 4를 다운받을 수 있다.
http://www.adoberia.co.kr/pds/down.html?src=text&kw=000026

-showsplash
org.eclipse.platform
--launcher.XXMaxPermSize
256M
-vm
C:\Program Files\Java\jdk1.6.0_07\bin\javaw.exe
-Dosgi.requiredJavaVersion=1.5
-vmargs
-Xms40m
-Xmx512m

Flex 2 기반으로 근 2년 이상 한글문서를 담당했던 Flexdocs.kr 서비스를 하지 못하게 되었습니다. 그동안 Flexdocs.kr은 제 개인서버에서 서비스 했습니다. 한글작업을 위해 몇몇분들이 관심을 가지고 지속적으로 수정했지만 개인서버라는 제약과 관심부족 그리고 그 서버를 유지하는데 있어서 필요이상의 개인자본을 넣어야한다는 부담이 있었습니다. 그래서 집에서 간단한 서버 구축으로 유지하려고 했으나 인터넷공급업체에서 80번 포트를 막아놓아 더 이상 서비스를 하기에는 불가능하게 되었습니다.(요즘 대부분 인터넷 공급업체는 80번 포트 이용을 막고 있습니다.)

flexdocs.kr의 문서는 모두 제가 가지고 있습니다. 만약 flexdocs.kr을 계속 유지해야한다고 생각하시고 서버 호스팅을 무료로 해주실 수 있는 분이 있으시다면 연락부탁드리겠습니다. flexdocs.kr은 Apache, php, mysql이 지원되야하며 svn과 mod_rewrite등이 지원되면 되겠습니다.

이 문서는 누구의 소유가 아닙니다. 상업적 용도로 사용할 수 없습니다.

무사히 미국 LA에서의 일정을 보내고 돌아왔습니다. 주요 목적은 Adobe MAX 행사 참석이였습니다.

ACC(Adobe Community Champion)의 1년 활동평가를 통해 발탁되어 좋은 기회를 가지게 되었습니다.

행사기간은 3일이였으며 남는 시간에는 미국의 가족들과 오붓한 시간도 보냈습니다. ^^

참석한 Adobe MAX는 Adobe의 가장 큰 행사중에 하나로 1년에 한번씩 미국의 주요 도시를 돌면서 열립니다.  이번 행사 참여로 Adobe 로드맵에 대해서 어느 정도 알 수 있게 되었습니다.

이 로드맵의 첫번째 단추는 Adobe의 기술의 핵심인 Flash Player을 모든 플랫폼에 적용하는 겁니다. 이 플랫폼이라는 것은 모바일이 될 수 있고  각종 다른 기기들이 될 수 있을겁니다. 이것이 가능하게 하기 위해 Adobe는 Open Screen Project(http://www.openscreenproject.org/) 라는 것에 참여하고 있습니다. 이 프로젝트로 각종 기업에서 만들어지는 모바일등의 디바이스에 Flash Player가 설치되고 이미 엄청나게 보급화 되어 있는 Flash 개발인력을 어렵지 않게 흡수 시킬 수 있게 됩니다.

Open Screen Project를 반영하여 탄생된 것이 바로 Flash Player 10.1 입니다. 이 Flash player 10.1은 데스크탑 뿐 아니라 모바일에도 최적화되어 돌아갈 수 있도록 메모리 및 속도 향상에 큰 변화를 가져왔습니다. 그리고 기존에 Flash Lite로만 개발했던 인력을 ActionScript 3.0, Flex 개발자들까지 모바일 프로그램을 할 수 있도록 된거지요. 메모리,속도향상등에 더욱 자세한 내용을 보고 싶다면 제 블로그를 보세요.

http://blog.jidolstar.com/594

대부분의 개발자의 주요 관심사인 Apple의 경우 Open Screen Project에 참여하지 않고 있습니다. 그래서 Adobe는 Flash로 개발하고 아에 iPhone용 애플리케이션이 나오도록 해버렸습니다. 이미 어도비 Labs에 Flash로 만든 iPhone용 애플리케이션이 애플스토어에 올라왔다는 것을 확인할 수 있습니다. 현재 직접 아이튠즈에서 다운로드 받아볼 수 있습니다.

http://labs.adobe.com/technologies/flashcs5/appsfor_iphone/

Open Screen Project를 통해 대부분의 디바이스 및 각종 플랫폼에 Flash Player가 설치될 수 있도록 하여 Adobe가 얻을 수 있는 것은 Flash 애플리케이션의 유통일겁니다. Adobe가 내놓은 모든 것들이 이제는 모두 이 유통에 집중될 모양입니다. 이에 대한 구체적인 시스템이 바로 Flash Platform Service(http://www.adobe.com/devnet/flashplatform/services/index.html) 입니다. 아래링크는 제 블로그에 올린 Flash Platform Service에 대한 전문입니다.

http://blog.jidolstar.com/601

정리하자면, Adobe는 Open Screen Project를 통해 각종 디바이스에 Flash Player가 돌아갈 수 있도록 하여 시장은 선점하고 여기에 유통시장을 만들어 앱스토어 처럼 수익을 창출하겠다는 겁니다.

이것이 제가 Adobe MAX에 참석해서 파악한 Adobe가 나아가는 방향입니다.

(제가 정확히 파악했는지는 모르겠습니다. 사실 큰 회사의 전체적인 로드맵을 이 짧은 글에 담는 것은 많이 부족하겠지요. 잘못된 내용이나 보강할 내용있다면 댓글 또는 트랙백 걸어주시길 바랍니다.)

글쓴이 : 지돌스타(http://blog.jidolstar.com/603)

여러분은 지금 Flash로 만든 iPhone, iPod 용 애플리케이션을 애플 스토어에서 다운로드 받을 수 있습니다. Adobe Lab(http://labs.adobe.com)에서 올해 말에 나올 Flash Professional CS5를 홍보하기 위해 떡밥 제대로 내놯습니다. ^^

공식 페이지는 아래 링크를 찾아가세요.

http://labs.adobe.com/technologies/flashcs5/

http://labs.adobe.com/technologies/flashcs5/appsfor_iphone/

아래 이미지를 클릭하면 아이튠즈를 통해 받을 수 있습니다. 무료도 있고 유료도 있어요. (아이튠즈가 설치 되어있어야 겠죠?)

Chroma Circuit	Trading Stuff
Fickleblox	Just Letters
South Park	That Roach Game
Red Hood

Flash로 아이폰 프로그램을 만든다?!

Flash/Flex 개발자들 사이에서는 큰 반향일 일으킬게 분명합니다.

국내에도 곧이어 아이폰이 나온다는데 하고 싶은 개발의 폭이 한층 넓어지겠네요.

단! 기능은 기능일 뿐입니다.

사업적 가치를 위해서 어떻게 접근할 것인가는 Object-C든 Java든 ActionScript 든 같습니다.

아~ 그리고... 미국애들은 아이팟말고 아이폰만 사용하더군요. 덕분에 MAX 행사 내내 아이팟은 제대로 꺼내보지 못했습니다. ㅋ 그러니까 저 프로그램인 아이폰용으로만 작동될 수도 있다는 거죠. ^^

글쓴이 : 지돌스타(http://blog.jidolstar.com/602)

실무에 바로 쓸 수 있는있는 유용한 Flash/Flex 기반 ActionScript 3.0 라이브러리들입니다. 3번째 라이브러리도 조만간 소개하겠습니다. ^^

http://opencast.naver.com/FL188/12

글쓴이 : 지돌스타(http://blog.jidolstar.com/591)

실무에 바로 쓸 수 있는 유용한 Flash/Flex 기반 ActionScript 3.0 라이브러리들입니다.

이들을 이용해서 많은 테스트들이 이뤄졌으면 합니다. 물론 관련내용을 블로깅해서 트랙백도 걸어주시면 좋겠어요 ^^

다음주에는 다른 라이브러리를 소개하겠습니다.

http://opencast.naver.com/FL188/11

글쓴이 : 지돌스타(http://blog.jidolstar.com/590)

구를 표현하는데 있어서 많은 3D 예제들이 그냥 경도, 위도로 나눠서 텍스쳐 입히는 것이 대부분입니다. 사실 그게 가장 쉬운 방법이고 완성된 구를 표현할 것 같으면 그편이 좋습니다.

Geodesic Sphere에 대한 프로그램 코드는 그리 많지 않은 것 같더군요. 대신 건축물은 왜 이렇게 많은지.. ㅎㅎ 이 형태의 구로 만든 건축물이 매우 이쁘고 독특해보이죠. 디즈니랜드의 Epcot Dom이 매우 유명한 Geodesic Sphere의 한종류이죠.

응용하면 아래처럼 의자도 만들 수 있네요. 왠지 세련되어 보입니다.

Geodesic이라는 말은 두점간에 최단선(측지선)을 의미합니다. 이 원리를 이용해 만든 구가 바로 Geodesic 구라는 것이지요.

구글 어스(Google Earth)와 같은 3D 프로그램에서 구의 형태를 어떻게 표현했다고 생각하시나요? 정확히는 모르겠지만 Geodesic Sphere 기법을 이용했을 거라 추측합니다. 구글어스에 보이는 지도는 타일 이미지들의 모임입니다. 만약 경도,위도로 그 타일 이미지를 나눠버리면 결국 극쪽(북극, 남극)쪽에 불러와야할 타일 이미지는 엄청 많아지겠죠. 확대할수록 더할 겁니다. 이런 점에 비춰볼때 3D에서 Geodesic Sphere의 선택이 필요할 것 같아집니다.

Geodesic Sphere를 표현하는 방법은 다양합니다. TETRAHEDRON, OCTAHEDRON, ICOSAHEDRON 기반등을 이용해 그려나갈 수 있지요. 아래처럼요.

출처 : http://www.geepers.co.uk/software/geodesicsphere.html

아직 3D 지도에 어떤 방식이 좋을지 명확히 판단하지 못했지만 OCTAHEDRON 또는  ICOSAHEDRON  기반이 아닐까 생각합니다.

회전 : 마우스 드래그

폴리곤수 조절 : 방향키 Up/Down

Flash 3D API의 drawTriangle 메소드 기반으로 그려본겁니다. 일반 경도, 위도만을 가지고 그릴때보다 복잡한 편이라 애를 먹었습니다. 극부분이 이미지가 찌그러져보이는 것은 UV설정이 잘못되었기 때문입니다. 이부분에 대한 보완이 필요합니다. 어쨌든 3D 지도 기반을 만들기 위한 첫단추를 꽨 셈이군요. ^^

소스코드 아래 링크에서 볼 수 있습니다.

http://wonderfl.net/code/73c32973543fd5d1827ae725ae92f143784b5f97 

글쓴이 : 지돌스타(http://blog.jidolstar.com/589)

Flash에서 이미지 처리는 지금까지 BitmapData 조작이였다. 싱글스레드 기반의 Flash Player는 이미지 조작을 하기에 좋은 퍼포먼스를 가지기 어려웠다. 하지만 Flash Player 10부터 멀티스레드를 기반으로하는 Adobe Pixel Bender를 지원함에 따라 이제 이미지 프로세싱에 Flash의 막강화력을 보여줄 수 있게 되었다. Adobe Pixel Bender에 대한 국내 문서는 그다지 많지 않은 편이지만 앞으로 Flash/Flex/ActionScript 개발자들에게 각광받는 기술이 될 것임에 틀림없겠다.

Opencast 보러 가기 : http://opencast.naver.com/FL188/10

글쓴이 : 지돌스타(http://blog.jidolstar.com/588)

Adobe Flash, Flex, AIR 에 관련된 강좌들을 모아봤습니다.
공부하는데 큰 도움이 될 것이라 생각합니다.

http://opencast.naver.com/FL188/9

글쓴이 : 지돌스타(http://blog.jidolstar.com/583)

한글 에러 : ArgumentError: Error #2180: AVM1 내용(AS1 또는 AS2)이 AVM2(AS3) 내용으로 로드된 경우 AVM1 내용을 displayLis의 다른 부분으로 이동할 수 없습니다."

 

영문 에러 : ArgumentError: Error #2180: It is illegal to move AVM1 content (AS1 or AS2) to a different part of the displayList when it has been loaded into AVM2 (AS3) content.

이것은 Flash Player 9 버전으로 만들어진 애플리케이션에서는 발생하지 않는다. Flash Player 10 버전으로 만들어진 애플리케이션에서 위와 같은 문제가 발생한다.

위 에러가 발생하는 조건은 다음과 같다.

1. AVM2(ActionScript Virtual Machine 2)기반으로 만들어진 Flash 애플리케이션
   AVM2 기반이라는 것은 ActionScript 3.0 기반으로 만들어진 애플리케이션을 의미한다.
2. Flash Player 10 기반으로 컴파일한다.
   컴파일 옵션에서 Flash Player 버전을 9.0.124 등이 아닌 10.0.0을 기반으로 한다.
3. 위 두 조건하에서 AVM1기반으로 만들어진 SWF파일을 flash.display.Loader를 이용해 로드한다.
   AVM1 기반이라는 것은 ActionScript 1.0 또는 ActionScript 2.0 기반으로 만든 SWF파일을 의미한다.
4. Loader.contentLoaderInfo.content를 addChild() 한다.
   Loader는 외부의 이미지, 플래시 파일등을 로드해서 디스플레이 객체로 등록하는 일종의 wrapper역할을 담당한다. 이들을 로드완료하면 Loader.contentLoaderInfo.content에 해당 객체의 참조를 얻을 수 있다. 일반적으로 화면에 출력하기 위해 addChild( Loader ) 식으로 하면 되는데 이렇게 안하고 addChild( Loader.contentLoaderInfo.content ) 를 하는 경우다. 이것이 가능한 이유는 Loader.contentLoaderInfo.content 도 DisplayObject이기 때문이다.

위 조건에 맞춰서 ActionScript 3.0 기반으로 코딩을 아래와 같이 해보겠다.

package
{
	import flash.display.DisplayObject;
	import flash.display.Loader;
	import flash.display.LoaderInfo;
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.net.URLRequest;
	
	public class AVM1LoadTest extends Sprite
	{
		private var loader:Loader;
		
		public function AVM1LoadTest()
		{
			loader = new Loader();
			loader.contentLoaderInfo.addEventListener(Event.COMPLETE,onLoadComplete);
			loader.load( new URLRequest("avm1asset.swf") );	
		}
		
		private function onLoadComplete( event:Event ):void
		{
			var loaderInfo:LoaderInfo = event.target as LoaderInfo;
			trace( loader.numChildren );
			trace( loaderInfo.content.parent );
			var avm1asset:DisplayObject = loaderInfo.content;
			addChild( avm1asset );
			trace( loader.numChildren );
			trace( loaderInfo.content.parent );
		}
	}
}

위 프로그램을 Flash Player 9 버전으로 컴파일하고 실행해보자. (실행되는 Flash Player 버전은 10이어야 한다. 당연히 실험 애플리케이션이 Flash Player 9버전 뿐 아니라 10버전도 만들 것이기 때문이다.)

아래 화면과 같이 AVM1 기반 SWF를 예쁘게 출력해준다.

onLoadComplete() 안을 살펴보면 addChild() 앞뒤로 똑같은 trace()문이 있다. 이것은 addChild() 전후로 loader.numChildren과 loaderInfo.content.parent(이것은 loader.content.parent와 같다)의 변화를 살펴보기 위함이다. loader.numChildren은 Loader 객체에 로드된 AVM1객체가 자식으로 등록되어 있는 경우에는 1이 출력되고 그 반대는 0이 된다. loaderInfo.content.parent는 로드된 AVM1객체의 부모가 무엇인지 가리킨다.

결과는 다음과 같다.

1
[object Loader]
0
[object AVM1LoadTest]

무엇을 의미하는가? addChild()를 하기 전에는 AVM1객체는 Loader의 자식이지만 addChild() 후로는 AVM1LoadTest객체의 자식이 된다. AVM1LoadTest는 위 프로그램의 메인 클래스이다. 이것은 당연한 결과로 자식은 두개 이상의 부모를 가질 수 없는 것을 의미한다. Flash Player 9버전으로 만든 경우에는 이러한 코딩이 가능했다.

조건을 바꿔보자. 이제 위 프로그램을 Flash Player 10 버전으로 컴파일하고 실행해보자. 언급했던 에러가 발생한다.

"ArgumentError: Error #2180: AVM1 내용(AS1 또는 AS2)이 AVM2(AS3) 내용으로 로드된 경우 AVM1 내용을 displayLis의 다른 부분으로 이동할 수 없습니다."

무엇을 의미하는가? Flash Player 10 기반으로 만들어진 애플리케이션은 AVM1 객체를 AVM2 기반의 디스플레이 객체로의 이동을 불허한다. 즉 Loader에서 떠나지 못함을 의미한다.

Flash Player 10기반에서 AVM2 SWF를 로드한 경우는 addChild( loader.contentLoaderInfo.content ) 가 가능할까? 이것은 된다!

Flash Player 10에서 AVM1기반의 SWF는 부모로 Loader이어야만 하는 이유는 무엇일까? 사실 여기에 대한 답변을 나는 아직 찾지 못했다. 혹시 아시는 분은 댓글 및 트랙백을 부탁한다.

일본에서는 이미 이 문제로 고민한 사람이 꽤 있었다. 재미있게도 AVM1을 AVM2로 강제로 바이트 단위로 버전을 수정해 버려 로드해버리는 커스텀 Loader까지 만들어 배포하는 사람이 있었다. 좋은 방법인지는 모르겠지만 아무튼 이런 연구가 활발히 진행되는 일본이 부럽당.. ㅡㅡ

Illustrator의 벡터형식 데이터를 읽어들이는 방법(Loader 클래스편)

Illustrator의 벡터형식 데이터를 읽어들이는 방법(Embed 태그 편)

BeInteractive - AVM2에서 AVM1의 SWF를 억지로 로드하는 ForcibleLoader 

BeInteractive - AVM2에서 AVM2의 SWF를 억지로 로드하는 방식 해설

흑... 이것도 spark 프로젝트....

아래 내용도 보면 좋을거다.

로드한 SWF 내부에 작성된 ActionScript 3.0 클래스 이름 찾기

글쓴이 : 지돌스타(http://blog.jidolstar.com/582)

Flex Builder 또는 Flash Builder 에서 유용하게 사용할 수 있는 플러그인을 소개했습니다. 더 많을 것이라 생각하는데 함께 공유했으면 좋겠네요. 댓글, 트랙백 모두 환영합니다.

http://opencast.naver.com/FL188/8

참고로 Flash Builder는 아래 링크로 가서 다운받으세요.
http://www.adoberia.co.kr/pds/down.html?src=text&kw=000026 

글쓴이 : 지돌스타(http://blog.jidolstar.com/581)