지돌스타 - 쿠키랩 블로그

수만개의 입자를 이용한 유체 시뮬레이션 실행

package {
	import flash.display.*;
	import flash.events.*;
	import flash.geom.*;
	import flash.utils.*;
	
	import net.hires.debug.Stats;
	
	[SWF(width="465", height="465", backgroundColor="0x000000", frameRate="110")];
	/**
	 * BitmapData를 이용한 파티클 렌더링 속도 테스트 
	 * @see http://clockmaker.jp/blog/2009/04/particle/
	 */ 
	public class bitmap_liquid100000 extends Sprite {
		
		private const nums:uint=100000;
		private var bmpDat:BitmapData;
		private var vectorDat:BitmapData;
		private var randomSeed:uint;
		private var bmp:Bitmap;
		private var vectorList:Array;
		private var rect:Rectangle;
		private var cTra:ColorTransform;
		private var vR:Number;
		private var vG:Number;		
		private var timer:Timer;
		
		public function bitmap_liquid100000() {
			initialize();
		}
		
		private function initialize():void {
			//stage 관련의 설정
			stage.align=StageAlign.TOP_LEFT;
			stage.scaleMode=StageScaleMode.NO_SCALE;
			stage.frameRate=110;
			
			//파티클이 렌더링 되는 메인 Bitmap. 
			bmpDat=new BitmapData(465, 465, false, 0x000000);
			bmp=new Bitmap(bmpDat);
			addChild(bmp);
			
			//파티클의 가속도를 계산하기 위한 도움 BitmapData로서 perlinNoise가 적용된다. 
			vectorDat=new BitmapData(465, 465, false, 0x000000);
			randomSeed=Math.floor(Math.random() * 0xFFFF);
			vectorDat.perlinNoise(230, 230, 4, randomSeed, false, true, 1 | 2 | 0 | 0);
			//addChild(new Bitmap(vectorDat)); //만약 이 perlinNoise가 적용된 Bitmap을 보고 싶다면 주석을 풀자 
			
			//화면크기 
			rect=new Rectangle(0, 0, 465, 465);
			
			//파티클 궤적을 그리기 위함 
			cTra=new ColorTransform(.8, .8, .9, 1.0);
			vR = 0;
			vG = 0;
			
			//파티클을 넣기 위한 List
			vectorList=new Array();
			for (var i:uint=0; i < nums; i++) {
				//파티클 위치
				var px:Number=Math.random() * 465;
				var py:Number=Math.random() * 465;
				var pv:Point=new Point(px, py);
				//파티클 가속도
				var av:Point=new Point(0, 0);
				//파티클 속도 
				var vv:Point=new Point(0, 0);
				//파티클 위치,가속도,속도 정보를 List에 저장 
				var hoge:VectorDat=new VectorDat(av, vv, pv);
				vectorList.push(hoge);
			}
			
			//지속적인 파티클 렌더링을 위한 loop 함수 호출 
			addEventListener(Event.ENTER_FRAME, loop);
			
			//500ms마다 
			timer = new Timer(500, 0);
			timer.addEventListener(TimerEvent.TIMER, resetFunc);
			timer.start();
			
			//통계 
			addChild(new Stats);
		}
		
		private function loop(e:Event):void {
			//렌더링용 BitmapData를 colorTransform로 어둡게 하여 기존에 그려진 파티클의 궤적을 보이도록 함 
			bmpDat.colorTransform(rect, cTra);
			
			//파티클의 위치를 재계산하여 렌더링한다.
			var list:Array=vectorList;
			var len:uint=list.length;
			for (var i:uint=0; i < len; i++) {
				var dots:VectorDat=list[i];
				var col:Number=vectorDat.getPixel(dots.pv.x, dots.pv.y);
				var r:uint=col >> 16 & 0xff;
				var g:uint=col >> 8 & 0xff;
				dots.av.x+=(r - 128) * .0005; //적색을 x축 가속도로 사용
				dots.av.y+=(g - 128) * .0005; //녹색을 y축 가속도로 사용
				dots.vv.x+=dots.av.x;
				dots.vv.y+=dots.av.y;
				dots.pv.x+=dots.vv.x;
				dots.pv.y+=dots.vv.y;
				
				var _posX:Number=dots.pv.x;
				var _posY:Number=dots.pv.y;
				
				dots.av.x*=.96;
				dots.av.y*=.96;
				dots.vv.x*=.92;
				dots.vv.y*=.92;
				
				//stage 밖으로 이동했을 경우 처리. 3항 연산자 처리함 
				(_posX > 465) ? dots.pv.x=0 : (_posX < 0) ? dots.pv.x=465 : 0;
				(_posY > 465) ? dots.pv.y=0 : (_posY < 0) ? dots.pv.y=465 : 0;
				
				//1*1 pixel을 bitmapData에 렌더링 
				bmpDat.fillRect(new Rectangle(dots.pv.x, dots.pv.y, 1, 1), 0xFFFFFF);
			}
		}
		
		private var seed:Number = Math.floor( Math.random() * 0xFFFF );
		private var offset:Array = [new Point(), new Point()];
		private function resetFunc(e:Event) :void{
			//파티클의 가속도를 계산하기 위한 도움 BitmapData로서 perlinNoise를 변경 
			vectorDat.perlinNoise( 230, 230, 3, seed, false, true, 1|2|0|0, false, offset );
			offset[0].x += 20;
			offset[1].y += 20;
			
			//파티클 궤적을 표시하기 위한 부분을 변경  (조금씩 색변동이 일어난다)
			var dots:VectorDat = vectorList[0];
			vR += .001 * (dots.pv.x-232)/465;
			vG += .001 * (dots.pv.y-232)/465;
			( vR > .01 ) ? vR = .01:
				( vR < -.01 ) ? vR = -.01:0;
			( vG > .01 ) ? vG = .01:
				( vG < -.01 ) ? vG = -.01:0;
			
			cTra.redMultiplier += vR;
			cTra.blueMultiplier += vG;
			( cTra.redMultiplier > .9 ) ? cTra.redMultiplier = .9:
				( cTra.redMultiplier < .5 ) ? cTra.redMultiplier = .5:cTra.redMultiplier;
			( cTra.blueMultiplier > .9 ) ? cTra.blueMultiplier = .9:
				( cTra.blueMultiplier < .5 ) ? cTra.blueMultiplier = .5:cTra.blueMultiplier;         
		}
	}
}

import flash.geom.Point;

class VectorDat {
	public var vv:Point;
	public var av:Point;
	public var pv:Point;
	
	function VectorDat(_av:Point, _vv:Point, _pv:Point) {
		vv=_vv;
		av=_av;
		pv=_pv;
	}
}

입자의 가속도 계산을 위한 PerlinNoise가 적용된 BitmapData의 모습. 500ms단위로 계속 변한다.

Liquid100000.zip

private function loop(e:Event):void {
	bmpDat.lock();
	(생략)
	bmpDat.unlock();
}

import flash.geom.Point;

class VectorDat {
	public var vv:Point; //속도
	public var av:Point; //가속도
	public var pv:Point; //위치 
	
	function VectorDat(_av:Point, _vv:Point, _pv:Point) {
		vv=_vv;
		av=_av;
		pv=_pv;
	}
}

class VectorDat {
	public var vx:Number = 0; //x축 속도
	public var vy:Number = 0; //y축 속도
	public var ax:Number = 0; //x축 가속도
	public var ay:Number = 0; //y축 가속도
	public var px:Number; //x축 위치 
	public var py:Number; //y축 위치 
	
	function VectorDat( px:Number, py:Number ) {
		this.px = px;
		this.py = py;
	}
}

실행 화면

while(pt.next) {
   var dx:Number = pt.x - mouseX;
   var dy:Number = pt.y - mouseY;
   (중간생략)
   pt = pt.next;
}

var mx:Number, my:Number;
mx = mouseX;
my = mouseY;
while(pt.next) {
   var dx:Number = pt.x - mx;
   var dy:Number = pt.y - my;
   (중간생략)
   pt = pt.next;
}

/**
*  Constructor.
*  
*  @langversion 3.0
*  @playerversion AIR 1.5
*  @productversion Flex 4
*/
public function WindowedApplication()
{
	super();

	addEventListener(MouseEvent.MOUSE_DOWN, mouseDownHandler);
	addEventListener(FlexEvent.PREINITIALIZE, preinitializeHandler);
	addEventListener(FlexEvent.UPDATE_COMPLETE, updateComplete_handler);
	addEventListener(FlexEvent.CREATION_COMPLETE, creationCompleteHandler);

	var nativeApplication:NativeApplication = NativeApplication.nativeApplication;
	nativeApplication.addEventListener(Event.ACTIVATE, nativeApplication_activateHandler);
	nativeApplication.addEventListener(Event.DEACTIVATE, nativeApplication_deactivateHandler);
	nativeApplication.addEventListener(Event.NETWORK_CHANGE, dispatchEvent);

	nativeApplication.addEventListener(InvokeEvent.INVOKE, nativeApplication_invokeHandler);
	initialInvokes = new Array();

	//Force DragManager to instantiate so that it can handle drags from
	//outside the app.
	DragManager.isDragging;
}

/**
*  @private
*  Storage for the backgroundFrameRate property.
*/
private var _backgroundFrameRate:Number = 1;

/**
*  Specifies the frame rate to use when the application is inactive.
*  When set to -1, no background frame rate throttling occurs.
*
*  @default 1
*  
*  @langversion 3.0
*  @playerversion AIR 1.5
*  @productversion Flex 4
*/
public function get backgroundFrameRate():Number
{
	return _backgroundFrameRate;
}

/**
*  @private
*/ 
public function set backgroundFrameRate(frameRate:Number):void
{
	_backgroundFrameRate = frameRate;
}

/**
*  @private
*/
private function nativeApplication_activateHandler(event:Event):void
{
	dispatchEvent(new AIREvent(AIREvent.APPLICATION_ACTIVATE));

	// Restore throttled framerate if appropriate when application is activated.
	if (prevActiveFrameRate >= 0 && stage)
	{
	    stage.frameRate = prevActiveFrameRate;  
	    prevActiveFrameRate = -1;
	}
}

/**
*  @private
*/
private function nativeApplication_deactivateHandler(event:Event):void
{
	dispatchEvent(new AIREvent(AIREvent.APPLICATION_DEACTIVATE));

	// Throttle framerate if appropriate when application is deactivated.
	// Ensure we've received an updateComplete on the chance our layout
	// manager is using phased instantiation (we don't wish to store a
	// maxed out (1000fps) framerate).
	if ((_backgroundFrameRate >= 0) && (ucCount > 0) && stage)
	{
	    prevActiveFrameRate = stage.frameRate;
	    stage.frameRate = _backgroundFrameRate; 
	}
}

아래 소스는 다음 링크에서 다운로드 받으셔도 됩니다.

CPUReducing.zip

초급
Framerate를 줄일때의 시점을 선택하는데 가장 쉽고 유용한 방법은 NativeApplication에서 Event.ACTIVATE 와 Event.DEACTIVATE 이벤트를 사용하는 것이다. AIR로 만들어진 빈윈도우를 선택해서 사용할때 CPU사용율이 1.8%라면 다른 윈도우를 선택해 그 윈도우의 CPU 사용율이 0.4%까지 떨여졌다고 한다. 또한 framerate를 0.01로 지정하면 0.2%까지 떨어진다고 한다. 이에 대한 예제는 다음과 같다. 예제가 이해하기 쉬우므로 따로 설명하지 않겠다.

package {
	import flash.desktop.NativeApplication;
	import flash.display.NativeWindow;
	import flash.display.NativeWindowInitOptions;
	import flash.display.NativeWindowType;
	import flash.display.Sprite;
	import flash.display.StageAlign;
	import flash.display.StageScaleMode;
	import flash.events.Event;
	import flash.text.TextField;
	import flash.text.TextFieldAutoSize;
	import flash.utils.getTimer;
	
	/**
	 * CPU 사용 줄이기 예제 1 
	 * @author Yongho, Ji
	 * @since 2009.12.1
	 * @see http://blog.jidolstar.com/622
	 */ 
	public class Novice extends Sprite {
		private var __isActive:Boolean = false;
		private var __window:NativeWindow;
		private var __textField:TextField;
		public function Novice() {
			__init();
			var options:NativeWindowInitOptions = new NativeWindowInitOptions();
			options.type = NativeWindowType.UTILITY;
			
			__window = new NativeWindow(options);
			__window.width = 200;
			__window.height = 200;
			__window.title = "Novice";
			
			__textField = new TextField();
			__textField.autoSize = TextFieldAutoSize.LEFT;
			__textField.text = "";
			
			__window.stage.scaleMode = StageScaleMode.NO_SCALE;
			__window.stage.align = StageAlign.TOP_LEFT;
			
			__window.stage.addChild(__textField);
			__window.activate();
			__window.addEventListener(Event.CLOSING,__onClosing);
		}
		private function __init():void {
			NativeApplication.nativeApplication.addEventListener(Event.ACTIVATE, __onActive );
			NativeApplication.nativeApplication.addEventListener(Event.DEACTIVATE, __onDeactive );
			stage.addEventListener(Event.ENTER_FRAME,__onEnterFrame);
		}
		private function __onActive($event:Event):void {
			stage.frameRate = 50;
			__isActive = true;
		}
		private function __onDeactive($event:Event):void {
			stage.frameRate = 1;
			__isActive = false;
		}
		private function __onEnterFrame($event:Event):void {
			__textField.text =  "active:" + __isActive + " " + getTimer();
		}
		private function __onClosing($event:Event):void {
			NativeApplication.nativeApplication.exit();
		}
	}
}

package {
	import flash.desktop.NativeApplication;
	import flash.display.NativeWindow;
	import flash.display.NativeWindowInitOptions;
	import flash.display.NativeWindowType;
	import flash.display.Sprite;
	import flash.display.StageAlign;
	import flash.display.StageScaleMode;
	import flash.events.Event;
	import flash.events.MouseEvent;
	import flash.text.TextField;
	import flash.text.TextFieldAutoSize;
	import flash.utils.getTimer;
	/**
	 * CPU 사용 줄이기 예제 2 
	 * @author Yongho, Ji
	 * @since 2009.12.1
	 * @see http://blog.jidolstar.com/622
	 */ 
	public class Intermediate extends Sprite {
		private static const ACTIVE:int = 50;
		private static const INACTIVE:int = 1;
		private var __isActive:Boolean = false;
		private var __isScrolling:Boolean = false;
		private var __buffer:int;

		private var __window:NativeWindow;
		public function Intermediate() {
			__init();
			var options:NativeWindowInitOptions = new NativeWindowInitOptions();
			options.type = NativeWindowType.UTILITY;
			
			__window = new NativeWindow(options);
			__window.width = 200;
			__window.height = 200;
			__window.title = "Intermediate";
			
			var textField:TextField = new TextField();
			textField.y = 20;
			textField.width = 195;
			textField.height = 175;
			textField.multiline = true;
			textField.wordWrap = true;
			textField.border = true;
			textField.borderColor = 0xff0000;
			textField.text = "Adobe AIR는 다양한 OS(Windows, Mac, Linux)에 구동될 수 있는 애플리케이션을 만드는데 사용하는 일종의 Flash Platfom기술이다. Flash ActionScript 3.0이나 Ajax만으로도 AIR 애플리케이션을 만들 수 있기 때문에 기존에 웹개발자들이 다른 언어를 배우지 않고 일반 데스크탑용 애플리케이션을 만드는데 있어서 접근성이 좋다. 앞으로 AIR는 데스크탑뿐 아니라 모바일등과 같은 다양한 기기에도 적용될 예정이다.하지만 원천적으로 데스크탑용 애플리케이션과 비교해 그 적용범위가 아직까지 많은 부분 부족하고 복잡한 UI를 다루는데 있어서 성능문제가 걸릴 수 있다. 적용되는 범위는 AIR 2.0 Beta 버전이 오픈된 것을 볼 수 있었듯이 계속 발전해나갈 것이다. 또한 성능면에서도 마찬가지 일 것이다. 그래도 성능면에 있어서 개발자가 조금만 신경을 쓴다면 어떤 부분에 있어서 획기적으로 AIR 애플리케이션의 성능을 향상시킬 수 있다. 일전에 Reducing CPU usage in Adobe AIR라는 글을 보았다. 여기서는 매우 단순하고 쉬운 방법으로 framerate를 줄임으로서 CPU 사용율을 현격히 줄이는 방법을 소개하고 있다. ";

			__window.stage.scaleMode = StageScaleMode.NO_SCALE;
			__window.stage.align = StageAlign.TOP_LEFT;
			
			__window.stage.addChild(textField);
			__window.activate();
			__window.addEventListener(Event.CLOSING,__onClosing);
		}
		private function __init():void {
			NativeApplication.nativeApplication.addEventListener(Event.ACTIVATE, __onActive );
			NativeApplication.nativeApplication.addEventListener(Event.DEACTIVATE, __onDeactive );
			stage.addEventListener(MouseEvent.MOUSE_WHEEL, __onMouseWheel, true);
		}
		private function __onActive($event:Event):void {
			stage.frameRate = ACTIVE;
			__isActive = true;
			trace( "active" );
		}
		private function __onDeactive($event:Event):void {
			stage.frameRate = INACTIVE;
			__isActive = false;
			trace( "deactive" );
		}
		private function __onMouseWheel($event:MouseEvent):void {
			if( !__isActive ) {
				if ( !__isScrolling ) {
					stage.addEventListener(Event.ENTER_FRAME, __onEnterFrame, true);
				}
				stage.frameRate = ACTIVE;
				__isScrolling = true;
				__buffer = getTimer()+500;
			}
		}
		private function __onEnterFrame($event:Event):void {
			if( __buffer < getTimer() ) {
				stage.frameRate = INACTIVE;
				__isScrolling = false;
			}
		}
		private function __onClosing($event:Event):void {
			NativeApplication.nativeApplication.exit();
		}
	}
}

package {
	import flash.desktop.NativeApplication;
	import flash.display.NativeWindow;
	import flash.display.NativeWindowInitOptions;
	import flash.display.NativeWindowType;
	import flash.display.Shape;
	import flash.display.SimpleButton;
	import flash.display.Sprite;
	import flash.display.StageAlign;
	import flash.display.StageScaleMode;
	import flash.events.Event;
	import flash.events.MouseEvent;
	import flash.filters.BevelFilter;
	import flash.text.TextField;
	import flash.text.TextFormat;
	import flash.utils.getTimer;
	import flash.utils.setTimeout;
	/**
	 * CPU 사용 줄이기 예제 3 
	 * @author Yongho, Ji
	 * @since 2009.12.1
	 * @see http://blog.jidolstar.com/622
	 */ 
	public class Expert extends Sprite {
		public static const ANIMATING:int = 50;
		public static const ACTIVE:int = 24;
		public static const INACTIVE_VISIBLE:int = 5;
		public static const INACTIVE_INVISIBLE:int = 1;
		
		private var __isActive:Boolean = false;
		private var __isAnimating:Boolean = false;
		private var __window:NativeWindow;
		private var __buffer:int;
		
		public function Expert() {
			__init();
			var options:NativeWindowInitOptions = new NativeWindowInitOptions();
			options.type = NativeWindowType.UTILITY;
			
			__window = new NativeWindow(options);
			__window.width = 200;
			__window.height = 200;
			__window.title = "Expert";
			
			__window.stage.scaleMode = StageScaleMode.NO_SCALE;
			__window.stage.align = StageAlign.TOP_LEFT;
			
			//창을 감추기 버튼 
			var buttonSkin:Sprite = new Sprite;
			buttonSkin.graphics.beginFill( 0xff0000, 1.0 );
			buttonSkin.graphics.drawRect(0,0,100,50);
			buttonSkin.graphics.endFill();
			buttonSkin.filters = [new BevelFilter()];
			var textFormat:TextFormat = new TextFormat();
			textFormat.color = 0xffffff;
			textFormat.align = "center";
			var textField:TextField = new TextField();
			textField.defaultTextFormat = textFormat;
			textField.text = "창을 감추기(1초후에 나타남)";
			textField.width = 100;
			textField.multiline = true;
			textField.wordWrap = true;
			textField.y = buttonSkin.height/2 - textField.textHeight/2; 
			buttonSkin.addChild( textField );
			var button:SimpleButton = new SimpleButton(buttonSkin,buttonSkin,buttonSkin,buttonSkin);
			button.addEventListener(MouseEvent.CLICK, __onHide );
			__window.stage.addChild( button );
			
			//Animation 동작 시키기 버튼 
			buttonSkin = new Sprite;
			buttonSkin.graphics.beginFill( 0x0000ff, 1.0 );
			buttonSkin.graphics.drawRect(0,0,100,50);
			buttonSkin.graphics.endFill();
			buttonSkin.filters = [new BevelFilter()];
			textFormat = new TextFormat();
			textFormat.color = 0xffffff;
			textFormat.align = "center";
			textField = new TextField();
			textField.defaultTextFormat = textFormat;
			textField.text = "동작시키기(1 second)";
			textField.width = 100;
			textField.multiline = true;
			textField.wordWrap = true;
			textField.y = buttonSkin.height/2 - textField.textHeight/2; 
			buttonSkin.addChild( textField );
			button= new SimpleButton(buttonSkin,buttonSkin,buttonSkin,buttonSkin);
			button.y = 52;
			button.addEventListener(MouseEvent.CLICK, __onAnimate );
			__window.stage.addChild( button );			
						
			__window.activate();
			__window.addEventListener(Event.CLOSING,__onClosing);
		}
		private function __init():void {
			NativeApplication.nativeApplication.addEventListener(Event.ACTIVATE, __onActive );
			NativeApplication.nativeApplication.addEventListener(Event.DEACTIVATE, __onDeactive );
		}
		private function setFrameRate( frameRate:Number ):void {
			stage.frameRate = frameRate;
			trace( frameRate );
		}
		private function animate($duration:int = 1000):void {
			trace( "동작시작");
			setFrameRate( 50 );
			__buffer = getTimer() + $duration;
			if(!__isAnimating) {
				stage.addEventListener(Event.ENTER_FRAME,__onEnterFrame);
			}
		}
		private function active():void {
			if(!__isAnimating) {
				setFrameRate( ACTIVE );	
			} 
			trace( "active " );
		}
		private function deactive():void {
			if (!__isAnimating) {
				setFrameRate( (__window.visible) ? INACTIVE_VISIBLE : INACTIVE_INVISIBLE );
			}
			trace( "deactive " );
		}
		private function show():void {
			__window.visible = true;
			active();
		}
		private function hide():void {
			__window.visible = false;	
			deactive();
		}
		private function __onActive($event:Event):void {
			__isActive = true;
			active();
		}
		private function __onDeactive($event:Event):void {
			__isActive = false;
			deactive();
		}
		private function __onEnterFrame($event:Event):void {
			if( __buffer < getTimer() ) {
				trace( "동작끝");
				stage.removeEventListener(Event.ENTER_FRAME,__onEnterFrame);
				__isAnimating = false;
				if( __isActive ) {
					active();
				} else {
					deactive();
				}
			}
		}
		private function __onHide($event:MouseEvent):void {
			hide();
			setTimeout(show,1000);
		}
		private function __onAnimate($event:MouseEvent):void {
			animate( 1000 );
		}
		private function __onClosing($event:Event):void {
			NativeApplication.nativeApplication.exit();
		}
	}
}

아래 테스트 코드는 문제가 있었습니다. 왜냐하면 GCC 최적화 옵션에 대해서 명확히 이해를 못하고 사용했기 때문입니다. 그래서 잘못된 지식을 전하는 것을 우려해 그냥 내용만 훑어보시되 “Adobe Alchemy 수행속도 테스트와 깊이 이해하기”글을 덧붙여 읽어주시길 바랍니다. 제가 잘못된 내용을 적었다면 지적해주셨으면 합니다. 그리고 실무에 썼거나 테스트를 해보신 분이라면 그에 대해 소개도 부탁드릴께요.

Alchemy는 C/C++ 코드를 AVM2(ActionScript 3 Virtual Machine) 환경에서 동작하도록 해주는 도구이다. Alchemy를 이용해 기존에 있는 C/C++ 코드를 Adobe AIR, Adobe Flex, Adobe Flash 프로젝트에서 직접 활용할 수 있는 SWF 또는 SWC를 만들어낼 수 있다. 이에 대한 더욱 자세한 사항은 본인이 게재한 “C/C++와 Flash 플랫폼과의 만남. Alchemy 1부” 를 참고하기 바란다.

이 글은 Alchemy를 이용해 만들어진 SWC를 이용했을 때와 순수 ActionScript 3.0으로만 코딩했을 때 수행속도 차이를 비교해보는 것을 목적으로 한다.

Alchemy 속도 테스트

과연 Alchemy를 이용해서 C언어를 SWC로 변환한 코드의 수행속도에 진전이 있을까? 아래 c코드와 ActionScript 3.0 코드는 이를 테스트할 수 있도록 한다. c언어와 ActionScript 3.0에서 동일하게 ”sin( 0.332 ) + cos( 0.123 ) + tan(0.333) * log(3)” 식을 1백만번 반복한다.

컴파일하고 수행하는 방법은 “C/C++와 Flash 플랫폼과의 만남. Alchemy 1부”를 참고한다.

1. speedtest.c

#include <math.h>
#include "AS3.h"

static AS3_Val c_speed_test(void* self, AS3_Val args)
{
    int i;
    double result;
    for( i=0; i < 1000000; i++ )
    {
        result = sin( 0.332 ) + cos( 0.123 ) + tan(0.333) * log(3);
    }
    return AS3_Number(result);
}

int main()
{
    AS3_Val method = AS3_Function( NULL, c_speed_test );
    AS3_Val result = AS3_Object( "c_speed_test: AS3ValType", method );
    AS3_Release( method );
    AS3_LibInit( result );
    return 0;
}

2. AlchemySpeedTest.as

package {
    import cmodule.speedtest.CLibInit;

    import flash.display.Sprite;
    import flash.display.StageAlign;
    import flash.display.StageScaleMode;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.text.TextFormat;
    import flash.utils.getTimer;

    public class AlchemySpeedTest extends Sprite
    {
        public function AlchemySpeedTest()
        {
            stage.scaleMode = StageScaleMode.NO_SCALE;
            stage.align = StageAlign.TOP_LEFT;

            var loader:CLibInit = new CLibInit();
            var lib:Object = loader.init();
            var startTime:Number;

            startTime = getTimer();
            var cResult:String = "c returned value : " + lib.c_speed_test(null) + " delay time(ms) : " + (getTimer()-startTime);

            startTime = getTimer();
            var asResult:String = "as3 returned value : " + as3_speed_test() + " delay time(ms) : " + (getTimer()-startTime);

            var textField:TextField = new TextField();
            textField.text = cResult + "\n" + asResult;
            textField.width = 500;
            textField.autoSize = TextFieldAutoSize.LEFT;
            textField.wordWrap = true;
            textField.defaultTextFormat = new TextFormat( null, 12 );
            addChild(textField);

        }
        public function as3_speed_test():Number
        {
            var i:int;
            var result:Number;
            //var sin:Function = Math.sin;
            //var cos:Function = Math.cos;
            for (i = 0; i < 1000000; i++)
            {
            result = Math.sin( 0.332 ) + Math.cos( 0.123 ) + Math.tan( 0.333 ) * Math.log(3);
            }
            return result;
        }
    }
}

speedtest.c를 아래처럼 Alchemy로 컴파일하고 만들어진 speedtest.swc를 AlchemySpeedTest.as와 함께 mxmlc로 컴파일 한다.

gcc speedtest.c –swc –o speedtest.swc
mxmlc.exe –library-path+=speedtest.swc –target-player=10.0.0 AlchemySpeedTest.as

아래는 위 프로그램을 시행한 결과이다.

c returned value : 1.6983678388082433 delay time(ms) : 559
as3 returned value : 1.6983678388082433 delay time(ms) : 694

이 결과는 의외의 결과이다. C와 ActionScript 3.0과 같은 수행속도를 보였기 때문이다. 하지만 이 결과는 C코드를 컴파일 할 때 최적화하지 않았기 때문이다. 아래처럼 –03 –Wall 옵션을 넣고 다시 수행해보자. -O3는 최적화 옵션이고 –Wall(또는 –W)는 모든 경고를 출력하도록 한다.

gcc speedtest.c –03 –Wall –swc –o speedtest.swc
mxmlc.exe –library-path+=speedtest.swc –target-player=10.0.0 AlchemySpeedTest.as

컴파일한 SWF파일을 실행한 결과는 다음과 같다.

c returned value : 1.6983678388082433 delay time(ms) : 1
as3 returned value : 1.6983678388082433 delay time(ms) : 601

결론

위 실험 결과를 통해 Alchemy를 이용해 C/C++의 수행속도를 잘 활용하면 좋다는 것을 알 수 있었다. 가령, ActionScript 3.0으로 구동 시에 많은 부하가 있을 가능성이 있는 부분을 C로 만들어 Alchemy를 통해 최적화된 SWC로 라이브러리화 해서 사용한다면 여러분의 Flash/Flex/AIR 애플리케이션의 속도를 크게 향상시킬 수 있다. 구체적으로 Audio/Video, 데이터 형식 변환, 데이터 조작, XML 분석 및 암호화 기능, 물리 시뮬레이션등이 들어가는 코드에서 포퍼먼스 향상을 기대할 수 있겠다.

아래는 Alchemy가 C/C++코드를 ActionScript 3.0 코드로 완벽하게 변경하는가에 대한 의견이다.

(글쓴이 의견)

어떤 분은 Alchemy로 SWF를 만들어준다고 해서 C/C++코드가 전부 ActionScript 3.0으로 변환될 것이다라는 생각을 가질 수 있다. 하지만 실험 결과만 가지고 볼 때 틀리다는 것을 유추할 수 있다. Alchemy는 C/C++ 코드를 AVM2 환경에서 동작하도록 만들되 ActionScript 3.0과 함께 사용할 수 있도록 만들어준다. 즉 C/C++를 적절하게 변경하고 ActionScript 3.0과 통신할 수 있는 통로구를 마련해주는 것이 Alchemy의 목적이다. 만약 ActionScript 3.0으로만 변경되는 것이라면 빠른 수행속도를 기대하기 어려울 것이다.

(양병규님 의견)

컴파일러에 대해서 조금 관심을 가져보시면 알 수 있을텐데요…
음… 뭐랄까…
그 최적화라는 것이 불필요한 일은 안하고 같은 기능이라면 더 빠른 기능으로 대치하고.. 그런일을 하는 것이 컴파일러의 최적화인데요..
제가 보기에는
for( i=0; i < 1000000; i++ )
{
result = sin( 0.332 ) + cos( 0.123 ) + tan(0.333) * log(3);
}
이 부분이.. 최적화를 하면 루프를 1000000번 돌지 않고 한방에 끝낼것같습니다. 최적화알고리즘중에서 루프문안에서의 내용이 반복을 해도 변화가 없는 경우에는 루프를 한방에 끝내도록 하는 알고리즘이 있습니다. 이 예가 그런 예일것 같은데요..

암튼.. ActionScript에는 그런 최적화가 없는데 이미 오랜 역사동안 만들어진 C/C++언어의 최적화 기술이 적용되면 분명히 나은 결과를 보일 것 으로 예상됩니다. ^^;(물론 코딩하는 사람의 실력이 좋을 수록 최적화의 효과가 떨어지겠지만)

그리고..
저는 아무리 봐도 C/C++로 코딩한 것이 결국 몽땅 ActionScript로 만들어지는 것이 맞는 것 같습니다. SWF에는 ActionScript 이 외에 다른 실행코드는 존재하지 않습니다. 최종적으로 만들어진 결과가 *.SWF(*.SWC)이지 않습니까? SWF File Format Specification Version 10 문서 278페이지를 다 훑어봐도 ActionScript 이외에는 실행코드가 없습니다. 머.. DLL을 임포트한다거나 별도의 실행코드용 외부 라이브러리가 있다거나… 그런건 전혀 없습니다.

malloc 함수 같은 경우의 예를 들어보면 ActionScript에는 malloc과 동일한 역할을 하는 어셈블명령은 없습니다. 하지만 ActionInitArray와 같이 긴 변수를 사용할 수 있는 명령으로 ‘구현’은 할 수 있을겁니다. 아마도 그런 방법으로 구현되지 않았나싶습니다.

어쨋든 Alchemy는 C/C++을 100% ActionScript로 변환해 주는게 맞고.. 함수사용, 변수사용, 최적화, 수학함수의 구현, 각종 기초 알고리즘등 기초적인 부분에서 훨씬 우월하기 때문에 좋은 효과를 나타내고 있는 것으로 생각됩니다.

시간이 나면 Alchemy에서 만들어진 SWF 파일을 분석해 보면 아주 좋은 공부가 될것같습니다. ^^;

Alchemy가 유용한 것은 C/C++ 코드를 ActionScript 3.0와 함께 쉽게 사용할 수 있게끔 해주는 것과 C/C++자체가 가지는 빠른 수행속도를 Flash 컨텐츠에서 이용할 수 있는 것으로 생각한다. Alchemy가 앞으로 사용 편의성 향상과 여러 환경에서 문제없이 개발할 수 있도록 개선된다면 Adobe RIA기술이 한 단계 업그레이드 될 것이라 생각한다.

한가지 주의할 사항은 전부 C/C++로 만드는 것은 좋지 못하다. Alchemy를 적용하기에 앞서 본문에서 실험한 것과 같은 방법으로 여러가지 수행 테스트를 해보고 순수하게 ActionScript 3.0으로 한 것보다 큰 포퍼먼스를 기대할 수 있다고 판단했을 때 적용하는 것이 좋다. 때로는 어떤 코드냐에 따라 별로 큰 차이가 없을 수 있기 때문이다.

국내에 Alchemy를 응용한 많은 예제와 애플리케이션들이 나오길 바란다.

참고할 사이트

• C/C++와 Flash 플랫폼과의 만남. Alchemy 1부
• Alchemy 공식 홈페이지
• Alchemy Wiki 페이지
• GCC와 make 강좌